Getting a Specific Object from a Loader in Actionscript 3.0

Question

Hello.

I am learning ActionScript 3.0 and I am seeing this paradigm often:

package util
{
    import flash.display.Sprite;
    import flash.display.Bitmap;
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.net.URLRequest;
    import flash.events.Event;

    public class BitmapLoader extends Sprite
    {
     private var loader:Loader = new Loader();

     private var filePath:String;

     public function BitmapLoader(filePath)
     {
      this.filePath = filePath;

      loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeListener);
     }

     public function load():void
     {
      loader.load(new URLRequest(filePath));
     }

     private function completeListener(event:Event):void
     {
      addChild(loader);
     }
    }
}

What I would like to be able to do is get the object back rather that treat the loader as a DisplayObject. I will post my idealized version in the hopes that it will best explain what I would like to do.

package util
{
    import flash.display.Bitmap;
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.net.URLRequest;
    import flash.events.Event;

    public class BitmapLoader
    {
     private var hasLoaded:Boolean = false;
     private var loader:Loader = new Loader();

     private var filePath:String;
     private var bitmap:Bitmap;

     public function BitmapLoader(filePath)
     {
      this.filePath = filePath;

      loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeListener);
     }

     public function load():Bitmap
     {
      loader.load(new URLRequest(filePath));

      while(!hasLoaded);

      return bitmap;
     }

     private function completeListener(event:Event):void
     {
      bitmap = new Bitmap(Bitmap(LoaderInfo(event.target).content).bitmapData);
      hasLoaded = true;
     }
    }
}

What I'm missing is why the while loop never exits. Anyhow, this is sort of what I'd like to accomplish, so feel free to amend my example or post you preferred methods. Thanks!

Answer 1

this is improper:

bitmap = new Bitmap(Bitmap(LoaderInfo(event.target).content).bitmapData);

this is proper (notice the lack of new in this example):

bitmap = Bitmap(loader.content);

In terms of the while loop, you are freezing the Flash Player on that line. Flash is single threaded, all of the events that happen after your while clause never happen. it sits there waiting for the loop to break, which will never happen because there is nothing in the loop to break it. That is a limitation of the AVM.

Here's an extended example.

Answer 2

Hi Scott,

You cannot have this code:

public function load():Bitmap
{
    loader.load(new URLRequest(filePath));

    // this line can *never* work
    while(!hasLoaded);

    return bitmap;
}

You cannot return the bitmap from the load command. You have to exit the function after the request to load and write your code to be asynchronous.

Basically, what you need to write is:

1. Request the load
2. Wait for the completeListener callback
3. Use the Bitmap

So this should read:

public function load():void
{
    loader.load(new URLRequest(filePath));

    // remember you cannot return a Bitmap now.
    // It hasn't loaded yet. You can't wait in here
    // so just return.
}

private function completeListener(event:Event):void
{
    bitmap = new Bitmap(Bitmap(LoaderInfo(event.target).content).bitmapData);

    // HERE the bitmap is *now* available
    // you now need to tell your app that it is available so it can use it.
}