Simpler way to format bytesize in a human readable way?

Question

Hi,

I came up with the following solution to format an integer (bytesize of a file). Is there any better/shorter solution? I esacially don't like the float_as_string() part.

human_filesize(Size) ->
  KiloByte = 1024,
  MegaByte = KiloByte * 1024,
  GigaByte = MegaByte * 1024,
  TeraByte = GigaByte * 1024,
  PetaByte = TeraByte * 1024,

  human_filesize(Size, [
    {PetaByte, "PB"},
    {TeraByte, "TB"},
    {GigaByte, "GB"},
    {MegaByte, "MB"},
    {KiloByte, "KB"}
  ]).


human_filesize(Size, []) ->
  integer_to_list(Size) ++ " Byte";
human_filesize(Size, [{Block, Postfix}|List]) ->
  case Size >= Block of
    true ->
        float_as_string(Size / Block) ++ " " ++ Postfix;
    false ->
        human_filesize(Size, List)
end.

float_as_string(Float) ->
  Integer = trunc(Float), % Part before the .
  NewFloat = 1 + Float - Integer, % 1.<part behind>
  FloatString = float_to_list(NewFloat), % "1.<part behind>"
  integer_to_list(Integer) ++ string:sub_string(FloatString, 2, 4).

Edit: Fixed bug round() -> trunc()

Answer 1

http://stackoverflow.com/questions/1205506/calculating-a-round-order-of-magnitude/1205664

Answer 2

human_filesize(Size) -> human_filesize(Size, ["B","KB","MB","GB","TB","PB"]).

human_filesize(S, [_|[_|_] = L]) when S >= 1024 -> human_filesize(S/1024, L);
human_filesize(S, [M|_]) ->
    io_lib:format("~.2f ~s", [float(S), M]).

Note that this returns an iolist. If you need a string, you can convert that to binary and that to string.