ansaurus

Question

How sort elements and store them in a variable, XSLT

Answer 1

A:

Guess (don't have dev env to hand):

Add <xsl:value-of select="." />

Before the closing </xsl:for-each>

Murph 2010-02-16 10:37:58

Answer 2

+2 A:

Firstly, in your variable declaration, you do need to do something to create new nodes. Strictly speaking, you are not sorting them, but just reading through them in a given order. I think you need to add some sort of xsl:copy command.

<xsl:variable name="deposits"> 
  <xsl:for-each select="/BookingCostings/MultiDeposits"> 
    <xsl:sort select="substring(@DepositDate, 1, 4)" /> 
    <xsl:sort select="substring(@DepositDate, 6, 2)" /> 
    <xsl:sort select="substring(@DepositDate, 9, 2)" /> 
    <xsl:copy-of select=".|@*" />
 </xsl:for-each> 
</xsl:variable>

What this creates is a 'node-set', but to access it you will need to make use of an extension function in XSLT. Which one you use depends on the XSLT processor you are using. In the example I am about to give, I am using the Microsoft one.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ms="urn:schemas-microsoft-com:xslt" version="1.0">

Then, to access the nodes in your variable, you can do something like this

<xsl:value-of select="ms:node-set($deposits)/MultiDeposits[1]/@DepositDate" />

Here is a good article to read up on node-sets

Xml.com article on Node-Sets

Tim C 2010-02-16 11:36:04

Tim is right that inside your for-each you need to output something if you want to populate the variable so use that <xsl:copy-of select="."/> inside of the for-each. The type of the variable however is not node-set but rather result tree fragment. Only by calling the extension function on the variable the result tree fragment is converted to a node-set you can apply XPath to.

Martin Honnen 2010-02-16 12:05:57

Thank you guys! Yes, I definitely need <xsl:copy-of select="."/>.Tim thank you for the article it was helpful.Martin, do you know by any chance good read on tree fragments and how different function work on a document? Or for that matter any info on XSLT in general? I'd really appreciate it. Just trying to understand it all better :)

DashaLuna 2010-02-17 09:15:37

Answer 3

+2 A:

Using XSLT version 2.0 you could use perform-sort and tell that your variable is of type of a sequence of MultiDeposits using the as keyword (as="element(MultiDeposits)+")
Since your data is already as yyyy-mm-dd you can avoid to use the subtring to get each part of the date and use the sort directly on the field

with this sample xml:

<?xml version="1.0" encoding="ISO-8859-1"?>
<BookingCostings>
  <MultiDeposits depositDate="2001-10-09">1</MultiDeposits>
  <MultiDeposits depositDate="1999-10-09">2</MultiDeposits>
  <MultiDeposits depositDate="2010-08-09">3</MultiDeposits>
  <MultiDeposits depositDate="2010-07-09">4</MultiDeposits>
  <MultiDeposits depositDate="1998-01-01">5</MultiDeposits>
</BookingCostings>

and using the XSLT version 2.0 sheet:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;

 <xsl:template match="/">
 <html>
  <body>

  <xsl:variable name="deposits" as="element(MultiDeposits)+">
   <xsl:perform-sort select="BookingCostings/MultiDeposits">
    <xsl:sort select="@depositDate"/>
   </xsl:perform-sort>
  </xsl:variable>

  first date:<xsl:value-of select="$deposits[1]/@depositDate"/>,
  last date:<xsl:value-of select="$deposits[last()]/@depositDate"/>

  </body>
 </html>
 </xsl:template>

</xsl:stylesheet>

the ouput will be:

first date:1998-01-01, last date:2010-08-09

Patrick 2010-02-16 15:34:24

Thank you Patrick. I assume as="element(MultiDeposits)+" isn't possible in XSLT 1.0?Unfortunately, I don't have date in the format yyyy-mm-dd. I use function in every sort statement before substring function. I didn't mention it to simplify code a bit. I tried to have a local variable before sort statement with the whole date converted to yyyy-mm-dd but apparently sort instruction must be first. So yes.Thank you for the response :)

DashaLuna 2010-02-17 09:18:50

Unfortunately no, it is 2.0 only.

Patrick 2010-02-17 10:27:29

ansaurus

tags:

views:

answers:

How sort elements and store them in a variable, XSLT

related questions