How to extract a particular column of data in Perl?

Question

I have some data from a unix commandline call

1  ab  45  1234
2  abc 5
4  yy  999 2
3  987 11

I'll use the system() function for the call.

How can I extract the second column of data into an array in Perl? Also, the array size has to be dependent on the number of rows that I have (it will not necessarily be 4).

I want the array to have ("ab", "abc", "yy", 987).

Answer 1

use strict;
use warnings;

my $data = "1  ab  45  1234
2  abc 5
2  abc 5
2  abc 5
4  yy  999 2
3  987 11";

my @second_col = map { (split)[1] } split /\n/, $data;

To get unique values, see perlfaq4. Here's part of the answer provided there:

my %seen;
my @unique = grep { ! $seen{ $_ }++ } @second_col;

Answer 2

You can chain a Perl cmd-line call (aka: one-liner) to your unix script:

 perl -lane 'print $F[1]' data.dat

instead of data.dat, use a pipe from your command line tool

 cat data.dat | perl -lane 'print $F[1]'

Addendum:

The extension for unique-ness of the resulting column is straightforward:

cat data.dat | perl -lane 'print $F[1] unless $seen{$F[1]}++'

or, if you are lazy (employing %_):

cat data.dat | perl -lane 'print unless $_{$_=$F[1]}++'

Regards

rbo