How can I print the name of a given Perl variable (not its value)?

Question

Possible Duplicates:
Perl sub to print out a variable and its value
How to get name of object in perl

I'm trying to create a sub called "debug" in an existing Perl script (which runs as a CGI under Apache2) and I want to call it from any other sub in the script and pass it the name of a local variable in that sub in order to inspect (and print out) the variable's current value.

For example:

sub somesub {
  my $examplevar = 'abc';
  debug('examplevar');
  # or debug($examplevar); ??
}

The output in this case should be:

$examplevar: abc

I'm trying to avoid doing something like:

debug('examplevar', $examplevar);

because that's (and I'm hoping, unnecessary) extra typing.

The script has "use strict;" set and I've read "perldoc -q 'variable as a variable name'". Is there any way to achieve this without using symbolic references, while still only passing one parameter to the debug sub?

Answer 1

I think you are looking for PadWalker:

#!/usr/bin/perl

use strict; use warnings;

use Carp;
use PadWalker qw( peek_my );
use YAML;

my $x = 5;
my %h = ( a => 1, b => 2);

debug('$x', '%h', '@z');

sub debug {
    my $pad = peek_my(1);

    for my $var ( @_ ) {
        if ( exists $pad->{$var} ) {
            printf "%s =\n%s\n", $var, Dump($pad->{$var});
        }
        else {
            carp "Cannot locate variable '$var'";
        }
    }
    return;
}

Answer 2

Edit: fixed code, thanks to Eric Strom and Michael Carman for comments.

You can write a simple wrapper. For example:

sub debugvar
{
   my $name = shift;
   my $value = eval "return \$" . $name;
   debug ("$name = $value");
} 

....

$examplevar = 'abc';
debugvar('examplevar');
# outputs: $examplevar = abc

Also I recommend you take a look at Data::Dumper.

Note: this should work only for global variables, i.e. if you are using short scripts. For big scripts, please, use Sinan's solution with PadWalker.