Comparing filehandle with glob returned by IO::Select::can_read()

Question

Hello,

I am trying to manage three filehandles via IO::Select in perl. I have 1 input handle, 1 input/output handle, and 1 output handle. Im having a little trouble determining which filehandle is which when processing Select's return arrays of can_read() and can_write();

Example below

Any advice on how to actually compare these two filehandles? I've tried scalars, i've tried references, no references, etc. I can't think of why this isn't working.

#!/usr/bin/perl
use strict;
use warnings;
use IO::Select;

open(INPUT, "/dev/fd/3") or die "Unable to open input! $!";
my $stdin_buf;

# Main loop
while (1)
{
    foreach my $read_fh ($select->can_read(10)) # This DOES return INPUT as being readable
    {
        if ($read_fh == \*INPUT) # THIS fails.
        {
            read($read_fh, $stdin_buf, 512);
        }
    }
}

Answer 1

Use eq instead of == for this kind of comparison.

if ($read_fh eq *INPUT) { ... }

Answer 2

I got it working. It was a combination of using references and eq (which i had tried prior to fixing references);

working code:

#!/usr/bin/perl
use strict;
use warnings;
use IO::Select;

##############################################
# Asterisk to stream pipe thingie-ma-jig-bob #
# Written by Sean Powell - 10-5-10           #
##############################################

my $extension = $ARGV[0];

if (!$extension || $extension !~ /^\d+$/)
{
    print "USAGE: Please provide a decimal extension as the first parameter";
    exit(1);
}



my $ffmpeg = "/usr/bin/ffmpeg -f s16le -ar 8000 -ac 1 -i - -ab 64k -f mp3 -";
my $ezstream = "/usr/local/bin/ezstream -c /etc/asterisk/ICES/" . $extension . ".xml";

my $stdin_buf;
my $ffmpeg_buf;
my $last_activity = 0;

open(INPUT, "/dev/fd/3") or die "Unable to open input! $!";
open(FFMPEG, "|$ffmpeg") or die "Unable to fork off ffmpeg! $!";
open(EZSTREAM, "|$ezstream") or die "Unable to fork off ezstream! $!";
open(DEBUG, ">>/root/debug.log") or die "Unable to open debug log! $!";

my ($input_fh, $ffmpeg_fh, $ezstream_fh) = (*INPUT, *FFMPEG, *EZSTREAM);

my $select = new IO::Select(*INPUT);
$select->add(*FFMPEG);
$select->add(*EZSTREAM);

# Main loop
while (1)
{
    foreach my $read_fh ($select->can_read(10))
    {
        print DEBUG "Filehandle can read: $read_fh - $input_fh - $ffmpeg_fh - $ezstream_fh\n";
        if ($read_fh eq $input_fh)
        {
            my $read = read($read_fh, $stdin_buf, 512);
            print DEBUG "Read off $read bytes from INPUT\n";
            $last_activity = time();
        }
        if ($read_fh eq $ffmpeg_fh)
        {
            my $read = read($read_fh, $ffmpeg_buf, 512);
            print DEBUG "Read off $read bytes from FFMPEG\n";
            $last_activity = time();
        }
    }

    foreach my $write_fh ($select->can_write(10))
    {
        if ($write_fh eq $ffmpeg_fh && length($stdin_buf) > 0)
        {
            my $size = length($stdin_buf);
            my $wrote = syswrite($write_fh, $stdin_buf, $size);

            while ($wrote < $size)
            {
                $wrote += syswrite($write_fh, $stdin_buf, $size - $wrote, $wrote);
            }
            print DEBUG "Wrote $wrote bytes to FFMPEG\n";
            $last_activity = time();
            $stdin_buf = undef;
        }

        if ($write_fh eq $ezstream_fh && length($ffmpeg_buf) > 0)
        {
            my $size = length($ffmpeg_buf);
            my $wrote = syswrite($write_fh, $ffmpeg_buf, $size);

            while ($wrote < $size)
            {
                $wrote += syswrite($write_fh, $ffmpeg_buf, $size - $wrote, $wrote);
            }
            $ffmpeg_buf = undef;
            print DEBUG "Wrote $wrote bytes to EZSTREAM\n";
            $last_activity = time();
        }
    }
    last if (time() - $last_activity > 30);

}
close(INPUT);
close(EZSTREAM);
close(FFMPEG);