Can an XSL template match in *ALL* modes?

Question

Is there a way to write an XSL 1.0 template which is matching in all modes?

Or do I have to write a separate template for every existing mode (including additional templates for modes being added in the future)?

Here is what I have:

<xsl:apply-templates mode="mode1" />
    ...
<xsl:apply-templates mode="mode2" />
    ...
<!-- Do not process text content of nodes no matter in what mode -->
<!-- Is there a way to have only one template here? -->
<xsl:template match="text()" mode="mode1" />
<xsl:template match="text()" mode="mode2" />

Answer 1

The predefined mode: #all (only available in XSLT 2.0 however).

edit: replicating shared mode behaviour with 1.0

<xsl:template match="/">
 <xsl:variable name="choice" select="'a'"/><!-- input seed here -->
 <xsl:choose>
  <xsl:when test="$choice='a'">
   <xsl:apply-templates mode="a"/>
  </xsl:when>
  <xsl:when test="$choice='b'">
   <xsl:apply-templates mode="b"/>
  </xsl:when>
 </xsl:choose>
</xsl:template>

<xsl:template match="*" mode="a">
 [A]
 <xsl:apply-templates />
</xsl:template>

<xsl:template match="*" mode="b">
 [B]
 <xsl:apply-templates />
</xsl:template>

<xsl:template match="text()">
 [ALL]
</xsl:template>

Answer 2

If you want to have the template match in all modes then why are you using mode? If you don't use mode then the template will be used all the time. The reason for mode is to conditionally do different things with the same data type. Seems like you want modeless.

Answer 3

Is there a way to write an XSL 1.0 template which is matching in all modes

Yes, in order to do this one should follow these two rules:

1. Write your template without a mode attribute.

2. Within the moded templates have an <xsl:apply-templates> instruction without a mode attribute that will result in the template in 1. above being selected for processing

This follows directly from the XSLT 1.0 spec, which says:

If an xsl:apply-templates element has a mode attribute, then it applies only to those template rules from xsl:template elements that have a mode attribute with the same value; if an xsl:apply-templates element does not have a mode attribute, then it applies only to those template rules from xsl:template elements that do not have a mode attribute.

To summarise: A set of templates each in a different mode can still issue <xsl:apply-templates> in such a way (described above), so that the same specific, single template will be selected for processing in each case.

Answer 4

You can simulate your own mode-mechanism by passing a param and checking for that param in every template, just like that:

<xsl:template match="/">
    <xsl:apply-templates>
       <xsl:with-param name="mode">mode1</xsl:with-param>
    </xsl:apply-templates>

    <xsl:apply-templates>
        <xsl:with-param name="mode">mode2</xsl:with-param>
    </xsl:apply-templates>
</xsl:template>

<xsl:template match="text()" />

<xsl:template match="condition1">
    Matches in every mode.
</xsl:template>

<xsl:template match="condition2">
    <xsl:param name="mode" />
    <xsl:choose>
        <xsl:when test="$mode = 'mode1' or $mode = 'mode2'">
             Matches in Mode 1 and Mode 2
        </xsl:when>
        <xsl:when test="$mode = 'mode3'">
             Matches in Mode 3
        </xsl:when>
        <xsl:otherwise>Matches all other Modes</xsl:otherwise>
    </xsl:choose>
</xsl:template>

You could advance things even further by automatically generating XSL-T. Says: If you want some syntactic sugar or feature XSL 1.0 lacks you can extend your Stylesheet and write an XSL-T which translates the functionality into XSL 1.0.

For example, use your existing templates but instead of using mode as an XSL-T attribute introduce your own element, say <your:mode> and annotate existing templates. Another XSL-T might then transform that extended version into XSL 1.0 by simply copying contents and reproducing templates as needed, or into a format like shown in the example above.

It's quite tricky but works pretty well.