Why do I get “uninitialized value” warnings when I use Date::Manip’s UnixDate in a sort block?

Question

Related/possible duplicate: http://stackoverflow.com/questions/1263943/why-do-i-get-uninitialized-value-warnings-when-i-use-datemanips-sortbylength

This block of code:

my @sorted_models = sort { 
    UnixDate($a->{'year'}, "%o") <=>
    UnixDate($b->{'year'}, "%o") 
} values %{$args{car_models}};

kept generating the following error warning:

Use of uninitialized value in length at /.../Date/Manip.pm line 244.

Date::Manip is a CPAN module. And line 244 of Date::Manip is found within the following block of code:

# Get rid of a problem with old versions of perl
no strict "vars";
# This sorts from longest to shortest element
sub sortByLength {
    return (length $b <=> length $a);
}
use strict "vars";

But then including this (printing out the actual Unix Date value to the console in the logger) before the block of code to sort the values:

foreach (values %{$args{car_models}}) {
    $g_logger->info(UnixDate($_->{'year'},"%o")); 
}

removed the errors warnings entirely. Why? And what is a good fix instead of doing all these logging statements?

NOTE: None of the sorted values are undefined because when I printed them out in the logger, I could see that every one of them had a numerical value.

Answer 1

So I added that line of code to dump my data:

 my @sorted_models =    sort { $g_logger->info(Dumper{a=>$a,b=>$b});
                        UnixDate($a->{'year'}, "%o") <=>
                        UnixDate($b->{'year'}, "%o"); }
                        values %{$args{car_models}};

I was able to dump $a and $b ONCE, then I got the error like >50 times, followed by a dump of $a and $b for 20 or so times (I have 10 elements in my array)

Answer 2

Something is wrong with Date::Manip in the way it localizes special variables. Try to call Date_Init() before you do sorting. It seems to solve the problem:

use strict;
use warnings;

use Data::Dumper;
use Date::Manip qw(UnixDate Date_Init);
my $cars_ref = {
    mazda  => {model => 'mazda', year => '2008' },
    toyota => {model => 'toyota', year => '2001' },
    mitsu  => {model => 'mitsu', year => '2005' }
};

Date_Init(); # Initialize Date::Manip first!

my @models =
  sort {
    UnixDate( $a->{year}, '%o' ) <=> UnixDate( $b->{year}, '%o' );
  } values %$cars_ref;
print Dumper \@models;

Output:

$VAR1 = [
          {
            'model' => 'toyota',
            'year' => '2001'
          },
          {
            'model' => 'mitsu',
            'year' => '2005'
          },
          {
            'model' => 'mazda',
            'year' => '2008'
          }
        ];

Answer 3

I am going to one last time try to answer this as clearly as possible.

First, if all timestamps are like 2008-08-07T22:31:06Z, there is no need to map them through UnixDate as standard sort using cmp will sort them correctly.

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper;
use Date::Manip;

my %args = (
    car_models => {
        a => { year => '2009-08-07T22:31:06Z' },
        b => { year => '2008-08-07T23:31:06Z' },
        c => { year => '2008-08-07T21:31:06Z' },
    },
);

my @sorted_cmp = sort {
    $a->{year} cmp $b->{year}
} values %{ $args{car_models}};

print "Sorted *without* using UnixDate:\n";
print Dumper \@sorted_cmp;

my @sorted_dm = sort {
    UnixDate($a->{year}, '%o') <=> UnixDate($b->{year}, '%o')
} values %{ $args{car_models}};

print "Sorted using UnixDate:\n";
print Dumper \@sorted_dm;

Output (after setting TZ in cmd to placate Date::Manip):

C:\Temp> cars
Sorted *without* using UnixDate:
$VAR1 = [
          {
            'year' => '2008-08-07T21:31:06Z'
          },
          {
            'year' => '2008-08-07T23:31:06Z'
          },
          {
            'year' => '2009-08-07T22:31:06Z'
          }
        ];
Sorted using UnixDate:
$VAR1 = [
          {
            'year' => '2008-08-07T21:31:06Z'
          },
          {
            'year' => '2008-08-07T23:31:06Z'
          },
          {
            'year' => '2009-08-07T22:31:06Z'
          }
        ];

No warnings, no errors ... Ergo, all you have put on this page is one big mess of a red herring. Besides, this still does not explain where the 1249998666 in your other question came from.