How can I turn my Perl array to XML?

Question

How can I take a Perl array like this

@categories = ( ["Technology", "Gadgets"], ["TV & Film"] );

and generate this XML snippet?

<itunes:category text="Technology">
    <itunes:category text="Gadgets"/>
</itunes:category>
<itunes:category text="TV &amp; Film"/>

I can change the array if there's an easier way to get to the same output.

Answer 1

For a general approach of generating XML with perl have a look at XML::Generator or XML::Writer.

Answer 2

For starters, I would definately change the array. (There is no obvious mapping between the data and your desired XML fragment.)

Something like the following POO representation?

my $categories = { 
    "Technology" => {
        "Gadgets" => undef
    }, 
    "TV & Film" => undef
};

Answer 3

I actually think XML::Simple is one of the easiest xml modules to use depending on what you need.

The snippet you reference above though is not actually valid xml not having a root tag. Do you want to generate the snippet or a full valid xml document?

XML::Generator is another good one. Neither of those will generate the snippet you have there though since they will include a root tag.

Given your motivation for the question in your comment below you might want to look at: Mac::Itunes::Library::XML

And as a general corollary: Most of the time when dealing with perl search.cpan.org will find you what you need and http://cpanratings.perl.org/ will show you how well recieved something is by the community if the there are a lot of options.

Answer 4

I don't know why Inshalla answer has been downvoted because XML::Generator & XML::Writer are both good modules for writing out XML.

Using the Whats on iTunes? spec you commented on then this is how it could look using XML::Generator:

use strict;
use warnings;
use XML::Generator;

my $x = XML::Generator->new( pretty => 2, conformance => 'strict' );

my $itunes_ns = [ 'itunes' => 'http://www.itunes.com/dtds/podcast-1.0.dtd' ];

say $x->xmldecl( encoding => 'UTF-8' );
say $x->rss( 
    $x->channel(
        $x->title('All about Everything'),

        $x->category( $itunes_ns, { text => 'Technology' }, 
            $x->category( $itunes_ns, { text => 'Gadgets' } ),
        ),

        $x->category( $itunes_ns, { text => 'TV & Film' } ),
    ),
);

This produces:

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>

<rss xmlns:itunes="http://www.itunes.com/dtds/podcast-1.0.dtd"&gt;
  <channel>
    <title>All about Everything</title>
    <itunes:category text="Technology">
      <itunes:category text="Gadgets" />
    </itunes:category>
    <itunes:category text="TV & Film" />
  </channel>
</rss>

To answer the "turn perl array into XML" then here is one example:

use strict;
use warnings;
use XML::Generator;

my $x = XML::Generator->new( pretty => 2, conformance => 'strict' );

my $itunes_ns = [ 'itunes' => 'http://www.itunes.com/dtds/podcast-1.0.dtd' ];

my @categories = ( { "Technology" => [ "Gadgets", 'Gizmo' ] }, "TV & Film" );

say $x->xmldecl( encoding => 'UTF-8' );
say $x->rss( 
    $x->channel(
        $x->title('All about Everything'),

        map { recurse( $_ ) } @categories,
    ),
);

sub recurse {
    my $item = shift;
    return $x->category( $itunes_ns, { text => $item } ) 
        unless ref $item eq 'HASH';

    my ($k, $v) = each %$item;
    return $x->category( $itunes_ns, 
                         { text => $k }, 
                         map { recurse ( $_ ) } @$v );
}

Look at this previous SO question something a bit similar

/I3az/