Does XSLT have a Split() function?

Question

I have a string in a node and I'd like to split the string on '?' and return the last item in the array.

For example, in the block below:

<a>
    <xsl:attribute name="href">
        /newpage.aspx?<xsl:value-of select="someNode"/>
    </xsl:attribute>
    Link text
</a>

I'd like to split the someNode value.

Edit: Here's the VB.Net that I use to load the Xsl for my Asp.Net page:

Dim xslDocPath As String = HttpContext.Current.Server.MapPath("~/App_Data/someXslt.xsl")
Dim myXsltSettings As New XsltSettings()
Dim myXMLResolver As New XmlUrlResolver()

myXsltSettings.EnableScript = True
myXsltSettings.EnableDocumentFunction = True

myXslDoc = New XslCompiledTransform(False)
myXslDoc.Load(xslDocPath, myXsltSettings, myXMLResolver)

Dim myStringBuilder As StringBuilder = New StringBuilder()
Dim myXmlWriter As XmlWriter = Nothing

Dim myXmlWriterSettings As XmlWriterSettings = New XmlWriterSettings()
myXmlWriterSettings.ConformanceLevel = ConformanceLevel.Auto
myXmlWriterSettings.Indent = True
myXmlWriterSettings.OmitXmlDeclaration = True

myXmlWriter = XmlWriter.Create(myStringBuilder, myXmlWriterSettings)

myXslDoc.Transform(xmlDoc, argumentList, myXmlWriter)

Return myStringBuilder.ToString()

Update: here's an example of splitting XML on a particular node

Answer 1

Yes, use tokenize(string, separator):

tokenize("XPath is fun", "\s+")
Result: ("XPath", "is", "fun")

See the w3schools xpath function reference

[EDIT: Think I misunderstood the question. I thought you wanted to split the actual GET parameters after the ? into an array. For splitting a string at only ONE character, substring-after is your best bet.]

Answer 2

XSLT 1.0 doesn't have a split function per se, but you could potentially achieve what you're trying to do with the substring-before and substring-after functions.

Alternatively, if you're using a Microsoft XSLT engine, you could use inline C#.

Answer 3

I ended up using the substring-after() function. Here's what worked for me:

<a>
    <xsl:attribute name="href">
     /newpage.aspx?<xsl:value-of select="substring-after(someNode, '?')"/>
    </xsl:attribute>
    Link text
</a>

Even after setting the version of my XSLT to 2.0, I still got a "'tokenize()' is an unknown XSLT function." error when trying to use tokenize().

Answer 4

Just for the record, if you're doing this with 1.0, and you really need a split/tokenise, you need the xslt extensions.

Answer 5

Use a recursive method:

<xsl:template name="output-tokens">
    <xsl:param name="list" /> 
    <xsl:variable name="newlist" select="concat(normalize-space($list), ' ')" /> 
    <xsl:variable name="first" select="substring-before($newlist, ' ')" /> 
    <xsl:variable name="remaining" select="substring-after($newlist, ' ')" /> 
    <id>
     <xsl:value-of select="$first" /> 
    </id>
    <xsl:if test="$remaining">
     <xsl:call-template name="output-tokens">
      <xsl:with-param name="list" select="$remaining" /> 
     </xsl:call-template>
    </xsl:if>
</xsl:template>

Answer 6

.NET doesn't support XSLT 2.0, unfortunately. I'm pretty sure that it supports EXSLT, which has a split() function. Microsoft has an older page on its implementation of EXSLT.

Answer 7

Adding another possibility, if your template engine supports EXSLT, then you could use tokenize() from that.

For example:

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:str="http://exslt.org/strings"
                extension-element-prefixes="str">

...
  <a>
    <xsl:attribute name="href">
      <xsl:text>/newpage.aspx?</xsl:text>
      <xsl:value-of select="str:tokenize(someNode)[2]"/>
    </xsl:attribute>              
  </a>
...
</xsl:stylesheet>