time calculation in xslt

Question

I am using xsl version 2.0

I have a time field that I need to add 1 to. I am getting a formatted number from the the below node:

    <xsl:value-of select="Master/End/Timecode"/>
    <xsl:text>

The data in "Master/End/Timecode" looks like 01:00:00:00 basically time-- hours :minutes :seconds :frames the frames are a count from oo to 23. How to add 1 to the frames and have the seconds and minuts increment up if frames=23.

Example 01:00:59:23 plus 1 would give a result of 01:01:00:00. Any ideas

Answer 1

This sounds like something you'd either want to write a custom XPath function for, or process outside of XSLT. There are ways you could make this happen but they get very complex, very quickly.

Answer 2

Just convert it to frames, increment, and then convert back:

  <xsl:analyze-string select="Master/End/Timecode" regex="^(\d+):(\d+):(\d+):(\d+)$">
    <xsl:matching-substring>

      <!-- Split into components -->
      <xsl:variable name="hours"
                    select="xs:integer(regex-group(1))"/>
      <xsl:variable name="minutes"
                    select="xs:integer(regex-group(2))"/>
      <xsl:variable name="seconds"
                    select="xs:integer(regex-group(3))"/>
      <xsl:variable name="frames"
                    select="xs:integer(regex-group(4))"/>

      <!-- Calculate total amount of frames -->
      <xsl:variable name="total-frames"
                    select="$hours * 60 * 60 * 24 +
                            $minutes * 60 * 24 +
                            $seconds * 24 +
                            $frames "/>

      <!-- Add 1 frame -->
      <xsl:variable name="remaining-frames"
                    select="$total-frames + 1"/>

      <!-- Calculate new component values -->
      <xsl:variable name="new-hours"
                    select="$remaining-frames idiv (60 * 60 * 24)"/>
      <xsl:variable name="remaining-frames"
                    select="$remaining-frames mod (60 * 60 * 24)"/>
      <xsl:variable name="new-minutes"
                    select="$remaining-frames idiv (60 * 24)"/>
      <xsl:variable name="remaining-frames"
                    select="$remaining-frames mod (60 * 24)"/>
      <xsl:variable name="new-seconds"
                    select="$remaining-frames idiv 24"/>
      <xsl:variable name="new-frames"
                    select="$remaining-frames mod 24"/>

      <!-- Recombine components -->
      <xsl:value-of select="$new-hours"/>
      <xsl:text>:</xsl:text>
      <xsl:value-of select="$new-minutes"/>
      <xsl:text>:</xsl:text>
      <xsl:value-of select="$new-seconds"/>
      <xsl:text>:</xsl:text>
      <xsl:value-of select="$new-frames"/>

    </xsl:matching-substring>
  </xsl:analyze-string>