XSLT transform replacing a tag that appears periodically through document

Question

I have an xml document that I am transforming with xslt into an xsl-fo document. I have this tricky problem I've been trying to track down a solution to for a long time...

In my source xml I have a few tags interspersed throughout. I want to format these as underline in the resulting document, however I have not been able to do so.

I'm trying using code like this:

<xsl:template match="//em">
  <fo:inline text-decoration="underline">
    <xsl:apply-templates select="*|text()"/>
  </fo:inline>
</xsl:template>

The full XSLT looks like this:

<xsl:stylesheet 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fo="http://www.w3.org/1999/XSL/Format"
  version="1.0">



  <!-- match em tags -->
  <xsl:template match="//em">
    <fo:inline text-decoration="underline">
      <xsl:apply-templates select="*|text()"/>
    </fo:inline>
  </xsl:template>
  <xsl:template match="//u">
    <fo:inline text-decoration="underline">
      <xsl:apply-templates select="*|text()"/>
    </fo:inline>
  </xsl:template>

  <!-- match b tags -->
  <xsl:template match="//b">
    <fo:inline font-weight="bold">
      <xsl:apply-templates select="*|text()"/>
    </fo:inline>
  </xsl:template>

  <xsl:template match="//br">
    <fo:block><xsl:text>&#xA;</xsl:text></fo:block>
  </xsl:template>

  <xsl:template match="briefs">
    <fo:root>
      <fo:layout-master-set>
        <fo:simple-page-master master-name="Evidence" page-width="8.5in" page-height="11in" margin="1in">
          <fo:region-body margin-bottom=".5in" margin-top=".5in" region-name="xsl-region-body" />
          <fo:region-before extent="1em" region-name="xsl-region-before" />
          <fo:region-after extent="1em" region-name="xsl-region-after" />
        </fo:simple-page-master>
      </fo:layout-master-set>
      <xsl:for-each select="brief">
        <fo:page-sequence master-reference="Evidence">
        <fo:static-content flow-name="xsl-region-before" font-family="Times">
           <fo:block font-size="10pt" text-align="center" color="#666666">
            <fo:inline font-style="italic"><xsl:value-of select="title"/></fo:inline> by <xsl:value-of select="author"/>
           </fo:block>
        </fo:static-content>

        <fo:static-content flow-name="xsl-region-after" font-family="Times" font-size="10pt">
          <fo:table>
            <fo:table-column />
            <fo:table-column column-width="1in" />
            <fo:table-body>
              <fo:table-row>
                <fo:table-cell>
                  <fo:block text-align="left" color="#666"><xsl:value-of select="copyright"/></fo:block>
                </fo:table-cell>
                <fo:table-cell>
                  <fo:block text-align="right" font-weight="bold">
                    Page <fo:page-number/>
                  </fo:block>
                </fo:table-cell>
              </fo:table-row>
            </fo:table-body>
          </fo:table>
        </fo:static-content>

        <fo:flow flow-name="xsl-region-body" font-family="Times">
          <fo:block font-size="14pt" text-align="center" text-transform="uppercase" border-before-width="2pt" border-before-color="black" border-before-style="double" border-after-width="1pt" border-after-color="black" border-after-style="solid" background-color="#ccc">
            <xsl:value-of select="title"/>
           </fo:block>

          <xsl:for-each select="heading">
            <xsl:choose>
              <xsl:when test="@level = 2">
                <fo:block font-size="11pt" font-weight="bold" keep-with-next="always" text-transform="uppercase" padding-before="1em">
                  <xsl:value-of select="title"/></fo:block>
              </xsl:when>
              <xsl:when test="@level = 3">
                <fo:block font-size="10pt" font-weight="normal" keep-with-next="always" text-transform="uppercase" padding-before="1em">
                  <xsl:value-of select="title"/></fo:block>
              </xsl:when>
              <xsl:otherwise>
                <fo:block font-size="12pt" font-weight="bold" keep-with-next="always" text-transform="uppercase" padding-before="1em">
                  <xsl:value-of select="title"/></fo:block>
              </xsl:otherwise>
            </xsl:choose>

            <xsl:for-each select="content/item">
              <xsl:choose>
                <xsl:when test="@type = 'card'">
                  <!--Print the taglines-->
                  <fo:block font-size="10pt" font-weight="bold" padding-before="1em" keep-with-next="always">
                    <!--<xsl:number value="position()" format="1" />. -->
                    <xsl:value-of select="tagline"/>
                  </fo:block>

                  <!--Print the citation-->
                  <fo:block font-size="10pt" font-style="italic" keep-with-next="always" keep-together.within-page="always" margin-left=".25in" padding-before=".5em">
                    <!--<xsl:number value="position()" format="1" />. -->
                    <xsl:value-of select="citation" disable-output-escaping="yes" />
                  </fo:block>

                  <!--Print the body-->
                  <fo:block font-size="10pt" keep-together.within-page="always" margin-left=".25in" padding-before=".5em">
                    <!--<xsl:number value="position()" format="1" />. -->
                    <xsl:value-of select="quote" disable-output-escaping="yes" />
                  </fo:block>

                </xsl:when>
                <xsl:otherwise>
                  <fo:block font-size="10pt" padding-before=".5em"><xsl:value-of select="."/></fo:block>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:for-each>

          </xsl:for-each>


        </fo:flow>

      </fo:page-sequence>
      </xsl:for-each>
    </fo:root>
  </xsl:template>

</xsl:stylesheet>

Does anyone have any ideas? Thanks so much!!!!!

Answer 1

Not seeing the whole stylesheet doesn't help, but the match syntax should probably be match="em" not match="//em".

Answer 2

It isn't clear to me where your code is to actually "go wild" with the document - i.e. run the matches. If <briefs> is the root node, then I would expect to see some <xsl:apply-templates select="*"/> or similar at some point; otherwise you are only going to get the output as specified in the root match (and it will never apply your <em> etc matches).

If you want to process the entire document using substitutions only when defined, then the classic match is something like:

<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

Because this matches all nodes, and cascades, it runs for every node until a more specific match is found. So with the xslt:

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="bar">
  <BAR/>
</xsl:template>

Most nodes will be repeated "as is", but any <bar> elements will be replaced with <BAR/> (and without any attributes/content).

Note that even with this; you need to explicitly cascade if you expect child data to be processed by matches (as shown by the <bar> example above, which doesn't cascade). And I can't see any <xsl:apply-templates> in your <briefs> match.

Finally; the match="//em" is redundant; match="em" should suffice.

Answer 3

It seems like you are doing your XSLT imperitively instead of declaratively. MG is correct, I think you'll have more luck if you do less "for-each"-ing and more "apply-templates"-ing.

It looks like you aren't matching all your em nodes because you aren't applying the templates inside your master root template. I'm tempted to say that every place you have a for-each, you should probably be using an apply-templates instead, but that's a bit academic.