ansaurus

Question

XSLT: trying to do a contains() with a full XPath. Why does this fail?

Answer 1

+1 A:

I have a few other suggestions but you need to post the entire (relevant) XSLT before I can go on. At least the enclosing template is necessary.

EDIT: Here is my proposal for your stylesheet:

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:tmp="http://tempuri.org"
  exclude-result-prefixes="tmp"
>
  <tmp:config>
    <tmp:alert label="Agent Watcher" link="PrintPages/PrintAW.html" />
    <tmp:alert label="Intel vPro" link="PrintPages/PrintvPro.html" />
  </tmp:config>

  <xsl:variable name="everyAlert" select="
    /identifiers/sectionname/alert
  " />

  <xsl:template match="/">
    <html>
      <body>
        <!-- 8< snip -->
        <div style="...">
          <div style="...">
            <xsl:text>Table of Contents - </xsl:text>
            <a style="..." href="PrintPages/PrintAll.html">
              <img border="0" src="images/PrintButton.png" />
            </a>
          </div>
          <xsl:for-each select="document('')/*/tmp:config/tmp:alert">
            <xsl:call-template name="section" />
          </xsl:for-each>
        </div>
      </body>
    </html>
  </xsl:template>

  <xsl:template name="section">
    <xsl:variable name="this" select="." />
    <xsl:variable name="alerts" select="
      $everyAlert[contains(@name, $this/@label)]
    " />

    <xsl:if test="$alerts">
      <div style="...">
        <a href="#{translate($this/@label, ' ', '_')}">
          <xsl:value-of select="$this/@label" />
        </a>
        <a style="..." href="{$this/@link}">
          <img border="0" src="images/PrintButton.png" />
        </a>
        <ol style="...">
          <xsl:for-each select="$alerts">
            <li style="...">
              <a href="#{@name}"><xsl:value-of select="@name" /></a>
            </li>
          </xsl:for-each>
        </ol>
      </div>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

Key features:

efficient code reuse through a named template
printed sections are easily configurable
uses <xsl:text> elements to avoid unwanted whitespace in the output while retaining freedom to format the XSLT code properly
uses attribute literal notation (the curly braces {}) instead of verbose <xsl:attribute> elements
uses a temporary namespace to allow storing config data in the stylesheet itself
uses an <xsl:for-each> loop and the document() function to retrieve and work with that config data
the for-each makes use of the context to transport the current @label and @link so no <xsl:param> is necessary (the <xsl:template name="section"> runs in tmp:config/tmp:alert context, not in sectionname/alert context!)
uses a global variable ($everyAlert) to store all nodes for later use

Tomalak 2009-09-24 09:20:13

Thanks, I was able to glean exactly what I needed from your answer. I'll be honest it was more than I needed, and at the moment, more than I could handle. BUT...You're revision did give me some excellent ideas and it is definitely great code structure and use. I'll be using this as a reference as I continue cleaning and reforming my xsl.Thanks a ton.Kothoga

Kevsteelio 2009-09-25 14:46:54

Happy to help. If you still have a question about a certain part in the above code, don't be afraid to ask in another comment.

Tomalak 2009-09-25 16:05:55

ansaurus

tags:

views:

answers:

XSLT: trying to do a contains() with a full XPath. Why does this fail?

related questions