ansaurus

Question

XSLT - how to parse xml with recursive elements to Eclipse toc.xml?

Answer 1

+2 A:

I think the following does what you want:

<xsl:template match="BODY">
    <toc label="Sample Table of Contents">
     <xsl:apply-templates select="UL/LI/OBJECT"/>
  </toc>
</xsl:template>

<xsl:template match="OBJECT">
  <topic label="{param[@name='Name']/@value}" href="{param[@name='Local']/@value}">
    <xsl:apply-templates select="following-sibling::UL/LI/OBJECT"/>
  </topic>
</xsl:template>

samjudson 2009-10-12 09:41:07

Hi hi Hi:)Thanksit works.do you have recomendation regarding good sites to learn XSLT?

orly 2009-10-12 09:47:40

one last question regarding the xml:if the @value contains String such as:"aaaa#bbb" and i want only the "aaaa" part?

orly 2009-10-12 09:55:57

`substring-before(@value, '#')`

Tomalak 2009-10-12 10:05:32

@samjudson: +1. Now, this is a little bit shorter than mine. ;-)

Tomalak 2009-10-12 10:25:48

the syntax should be:href="{param[@name='Local']/substring-before(@value, '#')}"?

orly 2009-10-12 11:18:44

No, it is `href="{substring-before(param[@name='Local']/@value, '#')}"`.

Tomalak 2009-10-12 11:52:35

In XSLT 2.0 either will work, but in XSLT 1.0 only the latter will work.

samjudson 2009-10-13 08:05:03

Answer 2

+1 A:

Your main problem is this line:

<xsl:apply-templates select="//LI"  />

This produces a list of all <LI> elements in the input, and thus creates a flat output list. You can use the built-in recursion and "move with the flow", like this:

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

  <xsl:template match="BODY">
    <toc>
      <xsl:apply-templates select="OBJECT" />
      <xsl:apply-templates select="UL" />
    </toc>
  </xsl:template>

  <xsl:template match="UL">
    <xsl:apply-templates select="LI" />
  </xsl:template>

  <xsl:template match="LI">
    <topic>
      <xsl:apply-templates select="OBJECT" />
      <xsl:apply-templates select="UL" />
    </topic>
  </xsl:template>

  <xsl:template match="OBJECT">
    <xsl:apply-templates select="param" />
  </xsl:template>

  <xsl:template match="OBJECT/param">
    <xsl:variable name="attrName">
      <xsl:choose>
        <xsl:when test="@name = 'FrameName'">label</xsl:when>
        <xsl:when test="@name = 'Name'">label</xsl:when>
        <xsl:when test="@name = 'Local'">href</xsl:when>
      </xsl:choose>
    </xsl:variable>
    <xsl:if test="$attrName != ''">
      <xsl:attribute name="{$attrName}">
        <xsl:value-of select="@value" />
      </xsl:attribute>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

The output produced is:

<?xml version="1.0" encoding="utf-8"?>
<toc label="contents">
  <topic label="Title1" href="Ref1">
    <topic label="Title 2" href="Ref2">
      <topic label="Title3" href="Ref3"></topic>
      <topic label="Title4" href="Ref4"></topic>
    </topic>
    <topic label="Title5" href="Ref5"></topic>
  </topic>
  <topic label="Title6" href="Ref6"></topic>
</toc>

Note that I replaced your "mode" templates whith an <xsl:choose>. The rest is fairly obvious, I think.

Tomalak 2009-10-12 09:50:30

Answer 3

A:

Thanks very much for the answer , it worked like magic:)

one last question regarding the xml: if the @value contains String such as:"aaaa#bbb" and i want only the "aaaa" part?

orly 2009-10-12 09:56:38

@orly: Please delete this post - the answers section is meant to be for actual answers. :) Especially since you've asked the same as a more appropriate comment already. ;-)

Tomalak 2009-10-12 10:06:30

ansaurus

tags:

views:

answers:

XSLT - how to parse xml with recursive elements to Eclipse toc.xml?

related questions