ansaurus

Question

How do I apply templates to each selected node in a for-each?

Answer 1

+3 A:

I'd restructure it a little (if you do not need the sorting the for-each approach makes possible):

<xsl:template match="/album">
  <ol>
    <xsl:apply-templates select="track"/>
  </ol>
</xsl:template>

<xsl:template match="track">
  <li><a href="{@id}"><xsl:apply-templates/></a></li>
<xsl:template>

This looks shorter and more to the point, IMHO.

I guess your

    <xsl:for-each select="track">
       <li><xsl:apply-templates/></li>
    </xsl:for-each>

walks through all track elements with the for-each, and then applies the default rules to its descendants. So the content of the for-each has the same context node as the match="track" template has, and thus the match="track" template never matches.

If you really want to use the for-each in that way, you will need to change either of the following two things in your approach:

Add a name="track" attribute to the match="track" template, and then use <xsl:call-template/> from within the for-each (my idea, and worse than Tim C's)
Use Tim C's solution using <xsl:apply-templates select="."/>. This has the advantage of avoiding naming and keeping the possibility to sort the tracks.

ndim 2009-10-25 10:28:44

The restructuring solution seems less modular than I would like (it doesn't allow me to also include tracks in a `<dl>` or `<table>` somewhere else on the page/site, at least not using the same stylesheet), but you're probably right in that it's the smoothest solution for this example.

Jakob 2009-10-25 11:49:34

Answer 2

+3 A:

I would agree with 'ndim' that you should probably restructure your XSLT to do away with the xsl:for-each loop.

Alternatively, you could amend the xsl:apply-templates to select the current track node within the xsl:for-each

<xsl:for-each select="track">
   <li>
      <xsl:apply-templates select="." />
   </li>
</xsl:for-each>

Keeping the xsl:for-each would, at least, allow you to sort the tracks in another order, if desired.

Tim C 2009-10-25 10:43:00

Good catch on the sorting. I guess this is the best solution, due to the sorting.

ndim 2009-10-25 10:46:07

I could have sworn I already tried this, but I guess not. This is exactly what I was looking for, though!

Jakob 2009-10-25 11:44:59

Answer 3

A:

I think using apply-templates and template modes is the cleaner solution:

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

  <xsl:template match="/">
    <body>
      <xsl:apply-templates select="album" mode="ol" />
    </body>
  </xsl:template>

  <xsl:template match="album" mode="ol">
    <ol>
      <xsl:apply-templates select="track" mode="li" />
    </ol>
  </xsl:template>

  <xsl:template match="track" mode="li">
    <li>
      <xsl:apply-templates select="." />
    </li>
  </xsl:template>

  <xsl:template match="track">
    <a href="{@id}">
      <xsl:value-of select="." />
    </a>
  </xsl:template>


</xsl:stylesheet>

results in:

<body>
  <ol>
    <li>
      <a href="shove">Somebody To Shove</a>
    </li>
    <li>
      <a href="gold">Black Gold</a>
    </li>
    <li>
      <a href="train">Runaway Train</a>
    </li>
  </ol>
</body>

Tomalak 2009-10-26 12:15:32

Answer 4

A:

The for-each statement changes the context node from album to track. The apply-templates call by default applies templates to the child nodes of the context node which in your case are the child nodes of the track element. Hence your template which matches 'track' never gets hit.

PJL 2009-10-29 17:44:57

ansaurus

tags:

views:

answers:

How do I apply templates to each selected node in a for-each?

related questions