ansaurus

Question

Tabular record display with XSLT i.e. Records display x columns, then new row...

Answer 1

A:

I think you are roughly on the right lines, but you have an empty tr embedded in another tr which isn't going to do anything useful and may foul up browsers. If you post the HTML you expect then it will be clearer how to achieve it.

peter.murray.rust 2009-11-25 09:55:25

Answer 2

+1 A:

Check this out: How can I break a table row in xsl after a specified count?

Or also this:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;

  <xsl:template match="/">

    <div>
      <table style="width: 200px" border="1">

        <tr>
          <xsl:for-each select="data/record">
            <td>
              <xsl:value-of select="name" /><br />
              <xsl:value-of select="age" />
            </td>
            <xsl:if test="position() mod 4 = 0 and position() != last()">
              <xsl:text disable-output-escaping="yes">
                 &lt;/tr&gt;&lt;tr&gt;
              </xsl:text>
            </xsl:if>
          </xsl:for-each>
        </tr>

      </table>
    </div>

  </xsl:template>

</xsl:stylesheet>

Rubens Farias 2009-11-25 10:01:45

The second answer is simple and effective - there is a "gotcha" though, you need to catch for the case where the last row has exactly four items and *not* drop the extra break in.

Murph 2009-11-25 10:24:55

@Murph: I can't test it right now but a `and position != last()` should do the trick; I edited my answer to reflect this, ty

Rubens Farias 2009-11-25 10:30:22

@Rubens: I agree (I resisted the temptation to exercise my shiny new "edit" rights to make exactly the same change - not quite worked out the ettiquette of that yet!)

Murph 2009-11-25 11:12:54

Hi guys! thanks so much for all the examples.. really very useful. I like the simplicity of this answer, although I can see why the other answers (from Erlock below and the one above) have more flexibility perhaps.. but either way, really many thanks!

David S 2009-11-25 21:41:09

Answer 3

+1 A:

  <xsl:template match="/data">
    <div>
       <table style="width: 200px" border="1">
        <xsl:apply-templates select="record[position() mod 4 = 1]"/>
      </table>
    </div>
  </xsl:template>
  <xsl:template match="record">
    <row>
      <xsl:apply-templates select=". | following-sibling::record[position() &lt; 4]" mode="mode" />
    </row>
  </xsl:template>
  <xsl:template match="record" mode="mode">
    <cell>
      <xsl:value-of select="id"/>
    </cell>
    <xsl:if test="position() = last() and position() &lt; 3">
      <xsl:call-template name="complete-row">
        <xsl:with-param name="count" select="position()"/>
      </xsl:call-template>
    </xsl:if>
  </xsl:template>
  <xsl:template name="complete-row">
     <xsl:param name="count"/>
     <td>&#160;</td>
     <xsl:if test="($count + 1) &lt; 3">
        <xsl:call-template name="complete-row">
           <xsl:with-param name="count" select="$count + 1"/>
        </xsl:call-template>
     </xsl:if>
  </xsl:template>

mikesub 2009-11-25 10:40:07

forgot to change 'mode' name from default to something more sensible

mikesub 2009-11-25 10:43:37

@Rubens Farias: hacking node-tree output with xsl:text disable-output-escaping is no good.

mikesub 2009-11-25 10:45:53

I agree, mikesub

Rubens Farias 2009-11-25 12:16:52

Answer 4

A:

I wrote this a while ago (I've just adapted it to suit your XML schema):

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt; 

   <xsl:output method="html"/> 

   <xsl:variable name="M" select="5"/> 
   <xsl:variable name="C" select="2"/> 

   <xsl:template match="/"> 
      <html> 
        <body> 
           <table border="1"> 
             <xsl:for-each select="/data/record[position() mod ($M * $C) = 1]"> 
                <tr>
                  <xsl:for-each select=".|following-sibling::record[position() mod $M = 0 and position() &lt; $M * $C]">
                   <td>
                     <xsl:for-each select=".|following-sibling::record[position() &lt; $M]">
                      <xsl:value-of select="name"/><br/>
                      <xsl:value-of select="age"/>
                     </xsl:for-each>
                   </td>
                  </xsl:for-each>
                  <xsl:if test="position() = last()">
                   <xsl:call-template name="empty-cells">
                     <xsl:with-param name="nb" select="$C - ceiling(count(.|following-sibling::record) div $M)"/>
                   </xsl:call-template>
                  </xsl:if>
       </tr>
             </xsl:for-each> 
           </table> 
        </body> 
      </html> 
   </xsl:template> 

   <xsl:template name="empty-cells">
    <xsl:param name="nb"/>
    <xsl:if test="$nb &gt;= 1">
     <td/>
       <xsl:call-template name="empty-cells">
         <xsl:with-param name="nb" select="$nb - 1"/>
       </xsl:call-template>
    </xsl:if>    
   </xsl:template>


</xsl:stylesheet>

Variable C is the number of columns, and variable M is the number of records per cell.

Erlock 2009-11-25 15:45:43

ansaurus

tags:

views:

answers:

Tabular record display with XSLT i.e. Records display x columns, then new row...

related questions