What is the best way to slurp a file into a string in Perl?

Answer 1

# Takes the name of a file and returns its entire contents as a string.
sub getfile 
{
  my($filename) = @_;
  my($result);

  open(F, $filename) or die "OPENING $filename: $!\n";
  while(<F>) { $result .= $_; }
  close(F);

  return $result;
}

Answer 2

open(my $f, '<', $filename) or die "OPENING $filename: $!\n";
$string = do { local($/); <$f> };
close($f);

Answer 3

How about this:

use File::Slurp;
my $text = read_file($filename);

Answer 4

{
  open F, $filename or die "Can't read $filename: $!";
  local $/;  # enable slurp mode, locally.
  $file = <F>;
  close F;
}

Answer 5

Candidate for the worst way to do it! (See comment.)

open(F, $filename) or die "OPENING $filename: $!\n";
@lines = <F>;
close(F);
$string = join('', @lines);

Answer 6

See the summary of Perl6::Slurp which is incredibly flexible and generally does the right thing with very little effort.

Answer 7

I like doing this with a do block in which I localize @ARGV so I can use the diamond operator to do the file magic for me.

 my $contents = do { local $/; local @ARGV = $file; <> };

If you need this to be a bit more robust, you can easily turn this into a subroutine.

If you need something really robust that handles all sorts of special cases, use File::Slurp. Even if you aren't going to use it, take a look at the source to see all the wacky situations it has to handle.

Answer 8

Things to think about (especially when compared with other solutions):

1. Lexical filehandles
2. Reduce scope
3. Reduce magic

So I get:

my $contents = do {
  local $/;
  open my $fh, $filename or die "Can't open $filename: $!";
  <$fh>
};

I'm not a big fan of magic <> except when actually using magic <>. Instead of faking it out, why not just use the open call directly? It's not much more work, and is explicit. (True magic <>, especially when handling "-", is far more work to perfectly emulate, but we aren't using it here anyway.)

Answer 9

This is neither fast, nor platform independent, and really evil, but it's short (and I've seen this in Larry Wall's code ;-):

 my $contents = `cat $file`;

Kids, don't do that at home ;-).

Answer 10

In writing File::Slurp (which is the best way), Uri Guttman did a lot of research in the many ways of slurping and which is most efficient. He wrote down his findings here and incorporated them info File::Slurp.

Answer 11

use Path::Class;
file('/some/path')->slurp;

Answer 12

Here is a nice comparison of the most popular ways to do it:

http://poundcomment.wordpress.com/2009/08/02/perl-read-entire-file/