XML url link in Flash

Question

Hi, I am new to XML and am having a small problem in Flash. I have a number of buttons. Each of these buttons need to open up a different URL which is in a xml file (I have added only one button for now (banstead), as I wasn´t sure how to add more).

My XML:

<?xml version="1.0" encoding="utf-8"?>
<banstead targ="_self" href="http://www.marca.com"&gt; </banstead>

My AS:

weblinkXML = new XML();
weblinkXML.ignoreWhite = true;
weblinkXML.load("xml/counties.xml");
weblinkXML.onLoad = function (success)
{
  var url = weblinkXML.firstChild.attributes.href;
  banstead.onRelease = function ()
  {
    getURL(weblinkXML.url);
  }
}

For some reason when I test the movie and click on the button it doesn´t open the URL I requested.

Appreciate any help

Answer 1

You've defined the variable url, but then called a different (undefined) variable weblinkXML.url in your getURL call.

Try this instead:

weblinkXML.onLoad = function (success)
{
  trace("success is "+success);// success should be TRUE
  var url = weblinkXML.firstChild.attributes.href;
  trace("url = "+url);
  banstead.onRelease = function ()
  {
    trace("button pressed with "+url);
    getURL(url);
  }
}

---

To add more buttons, you might try changing your XML file to look more like this:

<?xml version="1.0" encoding="utf-8"?>
<button buttonName="banstead" targ="_self" href="http://www.marca.com"&gt; </button>
<button buttonName="chipstead" targ="_self" href="http://www.yahoo.com"&gt; </button>
<button buttonName="tadworth" targ="_self" href="http://www.google.com"&gt; </button>

Then make a loop which goes through the XML and makes a button for each item it finds:

weblinkXML = new XML();
weblinkXML.ignoreWhite = true;
weblinkXML.load("xml/counties.xml");
weblinkXML.onLoad = function(success) {
    trace("success = "+success);
    banstead._visible=FALSE;// hide the original button: we're making copies
    for (var i:Number = 0; i< weblinkXML.childNodes.length; i++) {
        var myName:String = weblinkXML.childNodes[i].attributes.buttonName;
        // make sure banstead is a MovieClip, not a button, otherwise duplicateMovieClip won't work!
        var myButton:MovieClip = banstead.duplicateMovieClip(myName, i+1);
        // I've assumed your button has a dynamic text field in it named buttonLabel:
        myButton.buttonLabel.text=myName;
        myButton._y=banstead._y+ i*(banstead._height+5);// position the new button
        myButton.href = weblinkXML.childNodes[i].attributes.href;
        myButton.onRelease = function() {
            getURL(this.href);// note that each button has it's own href variable
        };
    }
};

I have made some assumptions about how your project is set up... but I've tested it and it seems to work for me

Let me know how you get on (and don't forget to click the big tick mark to accept this answer if it has helped you - thanks).

Answer 2

0 Nice tut.. thanks^^

I was working with the multiple links...The links works perfectly but link's names don't show up -.-

I put it together in "banstead", I named "myName" and it's in dynamic text.

...what am I doing wrong??

Also , I'm using this xml url link for a video player AS2. This player is loaded into a main flash website.. Exporting the player works offline (without the link name)..but when I open the html with the main flash website the xml url doesn't open the url...-.-

Any sugestions^^

Thanks in advance.

Josh

Answer 3

Great tutorial. I have a question. I have put the barnstead MC inside another MC and when it runs the click through URL's don't work. How would you code myButton.onRelease function to work while inside another MC called ward2? Forrest