ansaurus

Question

Using an XML element value in an XSLT predicate

Answer 1

A:

You can use a variable

<xsl:variable name="author" select="authorID/text()" />

and then use it in the predicate

<xsl:value-of select="//author[@id=$author]/name"/>

pablochan 2010-02-25 16:53:28

Answer 2

A:

<xsl:template match="book">
    <xsl:variable name="authorID" select="@authorID"/>

    <div>
        <h2><xsl:value-of select="name"/></h2>
        <p><xsl:value-of select="synopsis"/></p> 
        <xsl:for-each select="/library/authors/author[@id=$authorID]">
            <ul>
                <li>Author: <xsl:value-of select="name"/></li>
            </ul>
        </xsl:for-each>
    </div>
</xsl:template>

Roland Bouman 2010-02-25 16:55:36

Answer 3

+5 A:

Avoid the // operator like the plague. It has really bad performance characteristics, especially when you nest it like you do (for-each //, value-of //).

Use canonical XPath expressions, like this. They perform much better:

<xsl:for-each select="/library/books/book">
  <div style="display:block; background-color:#999; padding:2px; margin:2px;">
    <h2><xsl:value-of select="name"/></h2>
    <p><xsl:value-of select="synopsis"/></p>
    <ul>
      <li>
        <xsl:text>Author: </xsl:text>
        <!-- use the current() function to access the current node (book) -->
        <xsl:value-of select="
          /library/authors/author[@id=current()/authorID]/name
        "/>
      </li>
    </ul>
  </div>
</xsl:for-each>

Better yet, declare an XSL key:

<xsl:key name="kAuthorById" match="author" use="@id" />

and access it with the key() function:

<xsl:value-of select="key('kAuthorById', authorID)/name" />

This method has by far the best performance, especially when the input documents get bigger.

You should also avoid <xsl:for-each>. Try to write templates and use template matching instead:

<xsl:template match="library">
  <body>
    <xsl:apply-templates select="books" />
  </body>
</xsl:template>

<xsl:template match="books">
  <h1>List of Books</h1>
  <xsl:apply-templates select="book" />
</xsl:template>

<xsl:template match="book">
  <div style="display:block; background-color:#999; padding:2px; margin:2px;">
    <h2><xsl:value-of select="name"/></h2>
    <p><xsl:value-of select="synopsis"/></p>
    <ul>
      <li>Author: <xsl:value-of select="key('kAuthorById', authorID)/name"/></li>
    </ul>
    </div>
</xsl:template>

Tomalak 2010-02-25 17:15:40

+1 for `key()`, I really should use that one more often myself.

Roland Bouman 2010-02-25 17:19:21

ansaurus

tags:

views:

answers:

Using an XML element value in an XSLT predicate

related questions