How do I perform string operations on variables in a for loop?

Question

This sounds dumb, but I can't get it to work. I think i just dont' understand the difference between %%v, %v% and %v

Here's what I'm trying to do:

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%v.jpg"

This successfully generates a thumbnail for each of the movies, but the problem is:

movie.flv -> movie.flv.jpg

So what I would like to do is pull the last 4 characters off %%v and use that for the second variable.

I've been trying things like this:

%%v:~0,-3%

But it's not working, nor are any of the iterations of that that I could think of.

Any ideas?

Answer 1

Use %%~nV to get the filename only.

Answer 2

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%~nv.jpg"

From "help for":

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

Answer 3

I am not as good at batch as the above (I use WSH or other script languages instead) but I can try and explain %%v %v and %v%.

The first two forms are used in a for loop. help for explains the difference, the first form is used in a batch file while the second one is used when typing (pasting) the command directly at the command prompt.

The last form just replaces the variable name (environment variable) with its value:

set FOO=C:\bar\foo
cd %FOO%\gah