How do I rename an attribute using XSLT?

Question

I have an xml like this:

<person name="foo" gender = "male" />

I want to transform it to

<person id="foo" gender="male" />

Is there a way to do that using XSLT?

• I will have a lot of child nodes in person

• I will have more attributes in the person.

Answer 1

This should do it, not quite sure of the {name()} but you could replace that with "person"

> <xsl:template match="person">
>       <xsl:element name="{name()}">
>         <xsl:attribute name="id">
>           <xsl:value-of select="@name"/>
>         </xsl:attribute>
>         <xsl:attribute name="gender">
>           <xsl:value-of select="@gender"/>
>         </xsl:attribute>
>       </xsl:element>
>     </xsl:template>

Answer 2

Here's a template you can use that you won't have to create a new attribute for every existing attribute. What you're doing is creating the "id" attribute and then outputting all the attributes except for "name".

The extra "apply-templates" is for any children that <person> might have. Remove it if you don't want to keep the children. (That sounds horrible, doesn't it? ;-)

I also included the identity transform template.

  <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="person">
      <person id="{@name}">
         <xsl:apply-templates select="@*[name() != 'name']"/>
         <xsl:apply-templates/>
      </person>
   </xsl:template>

Answer 3

This is very simple: Use the identity transform and create a template that transforms the name attribute:

<xsl:template match="node()|@*">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="@name">
   <xsl:attribute name="id">
      <xsl:value-of select="."/>
   </xsl:attribute>
</xsl:template>

This will leave everything in the document except for name attributes exactly as it is. If you only want to change the name attribute on person elements, put a more restrictive XPath in the template's match attribute, e.g. person/@name.