ansaurus

Question

Problem merging similar XML files with XSL

Answer 1

A:

I think I have an answer for you. It's not the most elegant but it works. Basically, you run the stylesheet against one of the XML files you are trying to merge and then you use the document function to gain access to the other XML file. Iterate through each record in the first XML file and find the matching point. Then iterate through the second document and find the matching record and pull the appropriate nodes in.

<?xml version="1.0" encoding="UTF-8"?>

<xsl:variable name="doc2" select="document('FourBabyMarcs.xml')"/>

<xsl:template match="/">
    <marc:collection>
        <xsl:for-each select="marc:collection/marc:record">
            <marc:record>

                <xsl:for-each select="marc:leader">
                    <xsl:copy-of select="."/>
                </xsl:for-each>

                <xsl:for-each select="marc:controlfield">
                    <xsl:copy-of select="."/>
                </xsl:for-each>

                <xsl:for-each select="marc:datafield">
                    <xsl:copy-of select="."/>
                </xsl:for-each>

                <xsl:variable name="ID">
                    <xsl:value-of select="marc:datafield[@tag='035']/marc:subfield[@code='a']"/>
                </xsl:variable>

                <xsl:for-each select="$doc2/*/marc:record">
                        <xsl:if test="marc:datafield[@tag='035']/marc:subfield[@code='a']=$ID">
                            <xsl:for-each select="marc:datafield">
                                <xsl:if test="@tag='650'">
                                    <xsl:copy-of select="."/>
                                </xsl:if>
                                <xsl:if test="@tag='654'">
                                    <xsl:copy-of select="."/>
                                </xsl:if>
                            </xsl:for-each>
                        </xsl:if>
                </xsl:for-each>
            </marc:record>
        </xsl:for-each>
    </marc:collection>
</xsl:template>

Laney 2010-05-05 20:43:34

Answer 2

A:

The following solution uses keys to make efficient lookups in the merged document. It is assumed that all datafield elements except the matching datafield should be copied, and that there will be at most one matching datafield for each record. The URL to the document that should be merged is passed as a parameter.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:marc="http://www.loc.gov/MARC21/slim"&gt;
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="mergeFile"/>
    <xsl:variable name="mergeDoc" select="document($mergeFile)"/>

    <xsl:key name="datafield" match="marc:datafield" 
        use="concat(@tag, '|', marc:subfield[@code='a'])"/>

    <xsl:template match="/">
        <xsl:apply-templates select="node()|@*"/>
    </xsl:template>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="marc:record">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
            <xsl:apply-templates select="marc:datafield" mode="merge"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="marc:datafield" mode="merge">
        <xsl:variable name="datafieldKey" 
                      select="concat(@tag, '|', marc:subfield[@code='a'])"/>
        <!-- Make the other document the context node with for-each, so that
             key lookups will consult that document instead of the source 
             document. -->
        <xsl:for-each select="$mergeDoc">
            <xsl:for-each select="key('datafield', $datafieldKey)">
                <xsl:copy-of select="preceding-sibling::*"/>
                <xsl:copy-of select="following-sibling::*"/>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

markusk 2010-05-06 20:36:01

ansaurus

tags:

views:

answers:

Problem merging similar XML files with XSL

related questions