ansaurus

Question

XSL Grouping Problem

Answer 1

+1 A:

Here is a simple XSLT 1.0 solution using the Muenchian Grouping Method:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kFieldById" match="Field"
  use="@id"/>

 <xsl:key name="kField1923"
  match="Field[@id='1923']" use="@value"/>

 <xsl:template match="/">
  <Records>
    <xsl:for-each select=
    "key('kFieldById', '1923')
         [generate-id()
         =
          generate-id(key('kField1923',
                          @value
                          )
                           [1]
                      )
          ]
    ">
     <Data>
         <Text1923>
           <xsl:value-of select="@value"/>
         </Text1923>

         <xsl:variable name="vSubfield3095" select=
           "key('kField1923',@value)
                         /../Field[@id='3095']
           "/>

         <xsl:variable name="vSubfield3096" select=
           "key('kField1923',@value)
                         /../Field[@id='3096']
           "/>

         <Avg3095>
           <xsl:value-of select=
            "sum($vSubfield3095/@value)
            div
             count($vSubfield3095)
            "/>
         </Avg3095>

         <Avg3096>
           <xsl:value-of select=
            "sum($vSubfield3096/@value)
            div
             count($vSubfield3096)
            "/>
         </Avg3096>
     </Data>
    </xsl:for-each>
  </Records>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document, the wanted, correct resul is produced:

<Records>
   <Data>
      <Text1923>Test 1</Text1923>
      <Avg3095>5.333333333333333</Avg3095>
      <Avg3096>5.333333333333333</Avg3096>
   </Data>
   <Data>
      <Text1923>Test 2</Text1923>
      <Avg3095>3</Avg3095>
      <Avg3096>4</Avg3096>
   </Data>
   <Data>
      <Text1923>Test 3</Text1923>
      <Avg3095>4</Avg3095>
      <Avg3096>4</Avg3096>
   </Data>
</Records>

Dimitre Novatchev 2010-05-09 17:21:59

Awesomne, thank you very much is this works great

Wail 2010-05-09 17:38:20

@Wail: Glad it was useful. How about upvoting + accepting the answer? :)

Dimitre Novatchev 2010-05-09 17:59:48

Accpeted answer and not sure why it does not allow me to up the vote for you . ANy ideas and I will be glad to up the vote perhapse I do not have enough points to vote?

Wail 2010-05-10 00:00:52

As soon as I get up to 15 will make sure I vote this up

Wail 2010-05-10 00:03:58

ansaurus

tags:

views:

answers:

XSL Grouping Problem

related questions