SQL Server: Can you help me with this query?

Question

I want to run a diagnostic report on our SQL Server 2008 database server.

I am looping through all of the databases, and then for each database, I want to look at each table. But, when I go to look at each table (with tbl_cursor), it always picks up the tables in the database 'master'.

I think it's because of my tbl_cursor selection :

    SELECT table_name FROM information_schema.tables WHERE table_type = 'base table'

How do I fix this?

---

Here's the entire code:

SET NOCOUNT ON

DECLARE @table_count INT
DECLARE @db_cursor VARCHAR(100)
DECLARE database_cursor CURSOR FOR
SELECT name FROM sys.databases where name<>N'master'
OPEN database_cursor
FETCH NEXT FROM database_cursor INTO @db_cursor
WHILE @@Fetch_status = 0
BEGIN

    PRINT @db_cursor    
    SET @table_count = 0

    DECLARE @table_cursor VARCHAR(100)
    DECLARE tbl_cursor CURSOR FOR
    SELECT table_name FROM information_schema.tables WHERE table_type = 'base table'
    OPEN tbl_cursor
    FETCH NEXT FROM tbl_cursor INTO @table_cursor
    WHILE @@Fetch_status = 0
    BEGIN

        DECLARE @table_cmd NVARCHAR(255)
        SET @table_cmd = N'IF NOT EXISTS( SELECT TOP(1) *  FROM ' + @table_cursor + ') PRINT N''     Table ''''' + @table_cursor + ''''' is empty'' '
        --PRINT @table_cmd --debug
        EXEC sp_executesql @table_cmd
        SET @table_count = @table_count + 1

    FETCH NEXT FROM tbl_cursor INTO @table_cursor
    END
    CLOSE tbl_cursor
    DEALLOCATE tbl_cursor

    PRINT @db_cursor + N' Total Tables : ' + CAST( @table_count as varchar(2) ) 
    PRINT N'' -- print another blank line   
    SET @table_count = 0    

FETCH NEXT FROM database_cursor INTO @db_cursor
END
CLOSE database_cursor
DEALLOCATE database_cursor




SET NOCOUNT OFF

Answer 1

It's easier to use table variables so you can add rows to @tablist using another dynamic SQL statement

SET NOCOUNT ON

DECLARE @table_count INT
DECLARE @dblist TABLE (DBName VARCHAR(100))
DECLARE @tablist TABLE (TableName VARCHAR(100))
DECLARE @dbname varchar(100), @tabname varchar(100)

INSERT @dblist 
SELECT name FROM sys.databases where name<>N'master'

SELECT TOP 1 @dbname = DBName FROM @dblist
WHILE @@ROWCOUNT <> 0
BEGIN

    INSERT @tablist (tableName)
    EXEC ('SELECT table_name FROM ' + @dbname + '.information_schema.tables WHERE table_type = ''base table'' ')

    SELECT TOP 1 @tabname = tableName FROM @tablist
    WHILE @@ROWCOUNT <> 0
    BEGIN

--do my stuff

        DELETE @tablist WHERE tableName =  @tabname
        SELECT TOP 1 @tabname = tableName FROM @tablist
    END

    DELETE @dblist WHERE DBName =  @dbname
    SELECT TOP 1 @dbname = DBName FROM @dblist
END

Answer 2

The problem is because you're actually always running the INFORMATION_SCHEMA.TABLES query under the master db context.

You'd need to convert the tbl_cursor block into dynamic SQL in order to fully qualify the query with the DB name.

e.g.

SELECT table_name FROM YourDatabase.INFORMATION_SCHEMA.TABLES WHERE....

is essentially what you need to be executing for that cursor.

Answer 3

You might have to create dynamic SQL. because information_schema will fetch objects only from the current active database against which you are running this query.

you can try sys.objects