Separating positive values from 'zero' values in an XSLT for-each statement

Question

I am traversing an XML file (that contains multiple tables) using XSLT. Part of the job of the page is to get the title of each table, and present that title with along with the number of items that table contains (i.e. "Problems (5)").

I am able to get the number of items, but I now need to separate the sections with 0 (zero) items in them, and put them at the bottom of the list of table titles. I'm having trouble with this because the other items with positive numbers need to be left in their original order/not sorted.

Here is the code for the list of titles:

<ul>
  <xsl:for-each select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title">
     <li style="list-style-type:none;">
     <div style = "padding:3px"><a href="#{generate-id(.)}">
     <xsl:variable name ="count" select ="count(../n1:entry)"/>
     <xsl:choose>
        <xsl:when test = "$count != 0">
           <xsl:value-of select="."/> (<xsl:value-of select="$count"/>)
        </xsl:when>
        <xsl:otherwise>
           <div id = "zero"><xsl:value-of select="."/> (<xsl:value-of select="$count"/>)</div>
        </xsl:otherwise>
     </xsl:choose>
     </a>
     </div>
     </li>
   </xsl:for-each>
</ul>

Right now, the "zero" div just marks each link as gray.

Any help regarding how to place the "zero" divs at the bottom of the list would be greatly appreciated. Thank you!

Edited code using zero/nonzero templates:

<xsl:for-each select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title">
   <li style="list-style-type:none;">
      <div style = "padding:3px"><a href="#{generate-id(.)}">
         <xsl:apply-templates select="n1:title[count(../n1:entry) != 0]" mode="nonzero" />
         <xsl:apply-templates select="n1:title[count(../n1:entry) == 0]" mode="zero" />
      </a>
      </div>
   </li>
</xsl:for-each>

Answer 1

You can create two templates to process the nodes with a mode attribute on each. A mode="zero" and a mode="nonzero", if you like.

<xsl:template match="n1:title" mode="zero">
  ...
</xsl:template>
<xsl:template match="n1:title" mode="nonzero">
  ...
</xsl:template>

Call the nonzero template, selecting items with a count > 0 and the zero template with count = 0.

<xsl:apply-templates select="n1:title[count(../n1:entry) &gt; 0]" mode="nonzero" />
<xsl:apply-templates select="n1:title[count(../n1:entry) = 0]" mode="zero" />

Place the call to the nonzero template above the call to the zero template.

Answer 2

You should traverse them seperately. You can accomplish this by using xsl:apply-templates instead of xsl:for-each

<xsl:template match=".... something ....">
  <ul>
    <xsl:apply-templates select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title[count(../n1:entry) != 0]"/>
    <xsl:apply-templates select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title[count(../n1:entry) = 0]"/>
  </ul>

</xsl:template>

<xsl:template match="n1:title" >
  <li style="list-style-type:none;">
    <div style = "padding:3px"><a href="#{generate-id(.)}">
      <xsl:variable name ="count" select ="count(../n1:entry)"/>
      <xsl:choose>
        <xsl:when test = "$count != 0">
          <xsl:value-of select="."/> (<xsl:value-of select="$count"/>)
        </xsl:when>
        <xsl:otherwise>
          <div id = "zero"><xsl:value-of select="."/> (<xsl:value-of select="$count"/>)</div>
        </xsl:otherwise>
      </xsl:choose>
    </a>
    </div>
  </li>

</xsl:template>

Answer 3

No mode is necessary and no conditional logic (<xsl:choose>).

Also, the transformation can use just one <xsl:apply-templates>:

<xsl:apply-templates select="n1:title>
  <xsl:sort select="count(../n1:entry) = 0" data-type="number"/>
</xsl:apply-templates>

Here are the two templates to be used:

<!-- There is one or more ../n1:entry -->
<xsl:template match="n1:title"[../n1:entry] >  
  ...  
</xsl:template> 

<!-- No ../n1:entry exists --> 
<xsl:template match="n1:title"[not(../n1:entry)]">  
  ...  
</xsl:template> 

Answer 4

Hi Danielle,

You probably are happy with what you've got, but I liked Dimitre's answer and wanted to make it work just for my own learning.

I've simplified (what I believe to be is) the input data:

<component>
  <section>
    <title>table 1</title>
    <entry/>
  </section>
  <section>
    <title>table 2</title>
  </section>
  <section>
    <title>table 3</title>
    <entry/>
    <entry/>
  </section>
</component>

and the resulting stylesheet:

<xsl:stylesheet
    version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;

  <xsl:output method="html" indent="yes"/>

  <xsl:template match="/component">
    <ul>
      <xsl:apply-templates select="section">
        <xsl:sort select="count(entry) = 0"/>
      </xsl:apply-templates>
    </ul>
  </xsl:template>

  <xsl:template match="section[entry]">
    <li>
      <xsl:value-of select="title"/>
      <xsl:text> (</xsl:text>
      <xsl:value-of select="count(entry)"/>
      <xsl:text>)</xsl:text>
    </li>
  </xsl:template>

  <xsl:template match="section[not(entry)]">
    <li>
      <div id="zero"><xsl:value-of select="title"/></div>
    </li>
  </xsl:template>
</xsl:stylesheet>

Here is the output I get:

<ul>
   <li>table 1 (3)</li>
   <li>table 3 (2)</li>
   <li>
      <div id="zero">table 2</div>
   </li>
</ul>

Thanks again to Dimitre for suggesting the solution he did. I like <xsl:apply-templates/> over <xsl:for-each/> because they feel more in the vein of XSL being declarative and are just a little bit more uncomfortable for me coming from an imperative scripting and programming background.

Thank you,
Zachary