ansaurus

Question

How can I modify a scalar reference passed to a subroutine reference?

Answer 1

+2 A:

Try this:

Converter->new->convert("./whatever.html", sub { ${$_[0]} =~ s/<html>/<xml>/i; });

You are getting an uninitialized value warning because the substitution isn't being given anything to operate on ($_ is undefined in its scope). You need to tell it where to find its value (in @_, as a reference).

If you want to be fancy you could make the coderef operate on all its args by default:

sub { map { $$_ =~ s/<html>/<xml>/i } @_ }

Ether 2010-05-17 23:10:27

For the map code example, I'm wondering what I'd want the return value to be. :)

brian d foy 2010-05-18 00:30:47

@brian: indeed; normally I'd write a conversion sub to return the new value(s), rather than use references.

Ether 2010-05-18 16:17:06

Answer 2

+3 A:

Remember that an s/// by itself operates on $_, but your scalar reference is being passed into your callback sub as an argument, and is therefore in the @_ array.

So you can just change your callback sub to something like this:

sub { my ( $ref ) = @_; $$ref =~ s/<html>/<xml>/i }

Or, you could take advantage of the aliased nature of Perl subroutine arguments, and modify it directly:

sub _convert_html { 
    ...
    $coderef->( $html );
}

and then

sub { $_[0] =~ s/<html>/<xml>/i }

(This will actually modify the original string, as long as the argument is a scalar variable and not a literal string.)

friedo 2010-05-17 23:11:26

Answer 3

+4 A:

If it were me, I would avoid modifying the scalar ref and just return the changed value:

sub _convert_html
{
    my ($self, $filename, $coderef) = @_;

    my $html = $self->slurp($filename);
    $html = $coderef->( $html ); #this modifies the html
    $self->save_to_file($filename, $html);
}

However, if you want to modify a sub's arguments, it is worth knowing that all sub arguments are pass-by-reference in Perl (the elements of @_ are aliased to the arguments of the sub call). So your conversion sub can look like:

sub { $_[0] =~ s/<html>/<xml>/ }

But if you really want to operate on $_, like you have in your desired code example, you need to make _convert_html() look like:

sub _convert_html
{
    my ($self, $filename, $coderef) = @_;

    my $html = $self->slurp($filename);

    $coderef->() for $html;

    $self->save_to_file($filename, $html);
}

The for is an easy way to properly localize $_. You can also do:

sub _convert_html
{
    my ($self, $filename, $coderef) = @_;

    local $_ = $self->slurp($filename);

    $coderef->();

    $self->save_to_file($filename, $_);
}

daotoad 2010-05-17 23:15:11

Thanks for the detailed explanation :-)

Mark 2010-05-18 00:20:38

That's a lot of copying: first onto the argument stack, then change it, and copy it back onto the argument stack. That can hurt if you have to process many, many pages.

brian d foy 2010-05-18 00:32:36

note that if speed is important, `local` is faster than `for` with one item

Eric Strom 2010-05-18 01:17:39

note that if you notice the difference in speed between local and for, you are doing something else wrong.

jrockway 2010-05-18 01:45:54

Also, Sub::AliasedUnderscore is a cleaner way than either local or for.

jrockway 2010-05-18 01:46:41

@brian, yeah it can be a lot of copying--especially since it looks like `save_to_file()` also makes a copy. Even so, I generally prefer to work on copies when possible; "spooky action at a distance" bugs won't happen if you work only on copies. However, if profiling or expected usage suggests that we need to be more efficient, then I would definitely put the kibosh on the extra copying and use references to speed things up. My default position is to favor robustness in my APIs over absolute efficiency. There are many cases where efficiency gains are worth making some sacrifices.

daotoad 2010-05-18 05:26:06

@jrockway, Nice module. Is there a reason why you localize the typeglob (`*_`) rather than just `$_`?

daotoad 2010-05-18 05:29:26

ansaurus

tags:

views:

answers:

How can I modify a scalar reference passed to a subroutine reference?

related questions