How can I also get an element's index when I grep through an array?

Question

Let's say I have this list:

my @list = qw(one two three four five);

and I want to grab all the elements containing o. I'd have this:

my @containing_o = grep { /o/ } @list;

But what would I have to do to also receive an index, or to be able to access the index in grep's body?

Answer 1

 

my @index_containing_o = grep { $list[$_] =~ /o/ } 0..$#list;  # ==> (0,1,3)

my %hash_of_containing_o = map { $list[$_]=~/o/?($list[$_]=>$_):() } 0..$#list
            # ==> ( 'one' => 0, 'two' => 1, 'four' => 3 )

Answer 2

Take a look at List::MoreUtils. You can do lots of handy things with arrays without having to roll your own version, plus it's faster (because it's implemented in C/XS):

use List::MoreUtils qw(first_index indexes);

my $index_of_matching_element = first_index { /o/ } @list;

For all matching indices, and then their corresponding elements, you can do:

my @matching_indices = indexes { /o/ } @list;
my @matching_values = @list[@matching_indices];

or just:

my @matching_values = grep { /o/ } @list;

Answer 3

This populates 2 arrays with what you want, looping through the input array once:

use strict;
use warnings;
my @list = qw(one two three four five);
my @containing_o;
my @indexes_o;
for (0 .. $#list) {
    if ($list[$_] =~ /o/) {
        push @containing_o, $list[$_];
        push @indexes_o   , $_;
    }
}