How can i define an ActionScript event handler function inline in AddEvent Listener

Question

I have an action listener :

myText.addEventListener(TextEvent.LINK,linkClickHandler);

As according to this, i need to write an event handler function seperate to handle the text link event.

Now my requirement is i need to write that function in the same line isntead of giving its name.ie, something like

mytext.addEventListenet(TextEvent.LINK, 
                 function(event:TextEvent) {....code comes here....});

can i do like this in AS3.What will the syntax for this if possible.

Also i want to know, wether i can pass one more extra param to the event handler other than event which is the default parameter.

Answer 1

Your code will work. Just need a return type on the function.

EDIT: A simple delegate class:

public class Delegate
{

    public var cb:Function;
    public var args:Array;

    public function Delegate(cb:Function, ...args)
    {
        this.cb = cb;
        this.args = args;
    }

    public static function create(cb:Function, ...args):Function {
        var functionProxy:Delegate = new Delegate(cb, args);
        return functionProxy._create;
    }

    public function _create(e:Object=null):void {
        var params:Array = new Array();
        if(e) {
            params.push(e);
        }

        for each (var o:Object in args[0]) {
            params.push(o);
        }
        cb.apply(null, params);
    }

}