Why can't I get a returned value from my custom class?

Question

package com.adam.etutorial

{ import flash.display.MovieClip; import flash.text.TextField; import flash.display.Sprite; import flash.text.TextFormat; import flash.display.Shape;

public class adamsboxmaker
{

    //(boxWidth, boxHeight, lineColour, lineThickness, beginFillColour, fillIf, fontcolour, fontsize, fonttype, textFormat, textWidth, textHeight, text, Xoffset, Yoffset, textIf)
    public function adamsboxmaker(boxWidth:Number,boxHeight:Number,lineColour:Number,lineThickness:int, beginFillColour:Number, fillIf:Boolean, fontColour:Number, fontSize:int, fontType:String, textWidth:Number, textHeight:Number, txt:String, Xoffset:Number, Yoffset:Number, textIf:Boolean)
    {

        createBox(boxWidth,boxHeight,lineColour,lineThickness, beginFillColour, fillIf, fontColour, fontSize, fontType, textWidth, textHeight, txt, Xoffset, Yoffset, textIf);


    }

    private function createBox(boxWidth:Number,boxHeight:Number,lineColour:Number,lineThickness:int, beginFillColour:Number, fillIf:Boolean, fontColour:Number, fontSize:int, fontType:String, textWidth:Number, textHeight:Number, txt:String, Xoffset:Number, Yoffset:Number, textIf:Boolean)
    {


        /*BUILD CONTAINER*/
        var container:MovieClip = new MovieClip();
        /*END CONTAINER*/

        /*BUILD BOX*/
        var theBox:Shape = new Shape();
        container.addChild(theBox);
        theBox.graphics.lineStyle(lineThickness, lineColour);

        if (fillIf == true)
        {
            theBox.graphics.beginFill(beginFillColour);
        }

        theBox.graphics.moveTo(0, 0);
        theBox.graphics.lineTo(boxWidth, 0);
        theBox.graphics.lineTo(boxWidth, boxHeight);
        theBox.graphics.lineTo(0, boxHeight);
        theBox.graphics.lineTo(0, 0);

        if (fillIf == true)
        {
            theBox.graphics.endFill();
        }
        /*END BOX*/

        if (textIf == true)
        {
            /*BUILD FORMATTING*/
            var myFormat:TextFormat = new TextFormat();
            myFormat.color = fontColour;
            myFormat.size = fontSize;
            myFormat.font = fontType;
            /*END FORMATTING*/

            /*BUILD TEXTFIELD*/
            var theText:TextField = new TextField();
            theText.text = txt;
            theText.x = Xoffset;
            theText.y = Yoffset;
            theText.width = textWidth;
            theText.height = textHeight;
            theText.wordWrap = true;
            theText.setTextFormat(myFormat);
            container.addChild(theText);
            /*END TEXTFIELD*/
        }
        container.visible = false;

    return container;

    }

}

}

This is my first crack at writing a class and after reading up this is what I have.

Essentially, I want to be able to write var txt:adamsboxmaker = new adamsboxmaker(parameters);

and have txt be a display object from the returned MovieClip. But that's not happening. Can someone point me in the right direction?

Answer 1

Ok. So the problem here is a little misunderstanding. You are creating an instance of a adamsboxmaker class and the reference is then automatically returned and stored in the txt variable. This is how Object Orientated languages work.

What you are trying to do is use a factory method to create an object. To implement this, change your createBox to a public static function

 public static function createBox(boxWidth:Number,boxHeight:Number,lineColour:Number,lineThickness:int, beginFillColour:Number, fillIf:Boolean, fontColour:Number, fontSize:int, fontType:String, textWidth:Number, textHeight:Number, txt:String, Xoffset:Number, Yoffset:Number, textIf:Boolean){

and remove the call from inside the constructor.

public function adamsboxmaker(boxWidth:Number,boxHeight:Number,lineColour:Number,lineThickness:int, beginFillColour:Number, fillIf:Boolean, fontColour:Number, fontSize:int, fontType:String, textWidth:Number, textHeight:Number, txt:String, Xoffset:Number, Yoffset:Number, textIf:Boolean)
{

           //removed call

}

Then all you need to do is

txt = adamsboxmaker.createBox(paramters);

Re: Question in comment

In this case you want your adamsboxmaker to be the box. So first make the class extend MovieClip

public class adamsboxmaker extends MovieClip
{

You can now consider the instance of this class to be the same as the container:MovieClip you were creating. Add this code into the constructor:

      public function adamsboxmaker(boxWidth:Number,boxHeight:Number,lineColour:Number,lineThickness:int, beginFillColour:Number, fillIf:Boolean, fontColour:Number, fontSize:int, fontType:String, textWidth:Number, textHeight:Number, txt:String, Xoffset:Number, Yoffset:Number, textIf:Boolean){

                    var theBox:Shape = new Shape();
                    addChild(theBox); //we add it to this, rather than a container
                    theBox.graphics.lineStyle(lineThickness, lineColour);

                    if (fillIf == true)
                    {
                        theBox.graphics.beginFill(beginFillColour);
                    }

                    theBox.graphics.moveTo(0, 0);
                    theBox.graphics.lineTo(boxWidth, 0);
                    theBox.graphics.lineTo(boxWidth, boxHeight);
                    theBox.graphics.lineTo(0, boxHeight);
                    theBox.graphics.lineTo(0, 0);

                    if (fillIf == true)
                    {
                        theBox.graphics.endFill();
                    }
                    /*END BOX*/

                    if (textIf == true)
                    {
                        /*BUILD FORMATTING*/
                        var myFormat:TextFormat = new TextFormat();
                        myFormat.color = fontColour;
                        myFormat.size = fontSize;
                        myFormat.font = fontType;
                        /*END FORMATTING*/

                        /*BUILD TEXTFIELD*/
                        var theText:TextField = new TextField();
                        theText.text = txt;
                        theText.x = Xoffset;
                        theText.y = Yoffset;
                        theText.width = textWidth;
                        theText.height = textHeight;
                        theText.wordWrap = true;
                        theText.setTextFormat(myFormat);
                        container.addChild(theText);
                        /*END TEXTFIELD*/
                    }
                    visible = false;
     }

Now you can go

txt = new adamsboxmaker(parameters);
addChild(txt);

Answer 2

Just couple of little thing to add that might have been missed.

As best practice all functions should have a return type EXCEPT for class constructors like and all classes should start upper case and be title case.

public class AdamsBoxMaker 
{ 
  public function AdamsBoxMaker() 
  { 
    //your constructor 
  }

  public function anotherMethod( someParameter : String ) : String 
  { 
    //returns a String 
    return someParameter += " awesome!"; 
  } 

  private function anotherPrivateMethod( someParameter : String ) : void 
  { 
    //returns nothing 
  } 

HTH