ansaurus

Question

Answer 1

+2 A:

This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kProdByType"
      match="product" use="productType"/>

 <xsl:template match="node()|@*" name="identity">
   <xsl:copy>
    <xsl:apply-templates select="node()|@*"/>
   </xsl:copy>
 </xsl:template>

 <xsl:template match="/products">
  <products>
    <xsl:apply-templates select=
     "product[generate-id()
             =
             generate-id(key('kProdByType', productType)[1])
             ]
     "/>
  </products>
 </xsl:template>

 <xsl:template match="product">
   <productType value="{productType}">
    <xsl:apply-templates mode="copy"
     select="key('kProdByType', productType)"/>
   </productType>
 </xsl:template>

 <xsl:template match="product" mode="copy">
  <xsl:call-template name="identity"/>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<products>
 <product>
  <productNumber>1</productNumber>
  <productType>TypeA</productType>
 </product>
 <product>
  <productNumber>2</productNumber>
  <productType>TypeB</productType>
 </product>
 <product>
  <productNumber>3</productNumber>
  <productType>TypeA</productType>
 </product>
 <product>
  <productNumber>4</productNumber>
  <productType>TypeC</productType>
 </product>
 <product>
  <productNumber>5</productNumber>
  <productType>TypeA</productType>
 </product>
</products>

produces the wanted, correct grouping:

<products>
    <productType value="TypeA">
        <product>
            <productNumber>1</productNumber>
            <productType>TypeA</productType>
        </product>
        <product>
            <productNumber>3</productNumber>
            <productType>TypeA</productType>
        </product>
        <product>
            <productNumber>5</productNumber>
            <productType>TypeA</productType>
        </product>
    </productType>
    <productType value="TypeB">
        <product>
            <productNumber>2</productNumber>
            <productType>TypeB</productType>
        </product>
    </productType>
    <productType value="TypeC">
        <product>
            <productNumber>4</productNumber>
            <productType>TypeC</productType>
        </product>
    </productType>
</products>

Do note: This is an example of the well-known Muenchian method for grouping, which is the fastest known gouping technique in XSLT 1.0.

XSLT 2.0 solution:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*" name="identity">
   <xsl:copy>
    <xsl:apply-templates select="node()|@*"/>
   </xsl:copy>
 </xsl:template>

 <xsl:template match="/products">
   <xsl:for-each-group select="product"
        group-by="productType">
     <productType value="{productType}">
      <xsl:apply-templates select="current-group()"/>
     </productType>
   </xsl:for-each-group>
 </xsl:template>
</xsl:stylesheet>

when this XSLT 2.0 transformation is applied on the provided XML document, exactly the same, correctly-grouped result is produced.

Dimitre Novatchev 2010-08-16 17:26:05

hmmm... thanks for this!I will inject it into my code, see how it works and let you know.This is cool cuz it opens up more possibilities for me.

Jimmmy 2010-08-16 18:25:35

@Jimmmy: I'm glad you found my answer useful. The SO way of expressing this is to accept the answer (by clicking on the check-mark picture next to the answer). :)

Dimitre Novatchev 2010-08-16 18:43:34

@Dimitre: +1 for XSLT 1.0 and XSLT 2.0 solutions. Also, adding your tag `xslt-grouping`

Alejandro 2010-08-16 19:51:17

Thank guys. I'm looking to see how the solution works for me in my actual case. I may have further questions which is why I haven't marked it as answered yet :) More to come!

Jimmmy 2010-08-17 16:53:36

@Jimmmy: Further questions will be new, separate questions. You and we are *done* with this question.

Dimitre Novatchev 2010-08-17 17:01:39

@Dimitre - Thanks! You got me set on the right path. The code you provided above wasn't quite what I was looking for, so I looked up the Muenchian Method and found a site http://www.jenitennison.com/xslt/grouping/muenchian.html that described it step by step and I was able to come up with a code that worked for my needs, which was a simple character deliniated peice of text that would support an AJAX operation. I have posted the code that worked for me. Thanks again. Without your help I would not have known what to look for!

Jimmmy 2010-08-17 18:06:09

Answer 2

A:

Dimitre got me going on the right path. Here is the code that I came up with that worked for my needs, a simple deliniated stream of output to support an AJAX call...

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
<xsl:output method="html" encoding="utf-8"/>
<xsl:key name="kProdByBrand" match="Products/Product" use="Brand"/>

 <xsl:template match="Products">
   <xsl:for-each 
     select="Product
     [generate-id() = generate-id(key('kProdByBrand', Brand)[1])]"><xsl:sort
     select="Brand" /><xsl:value-of select="Brand" />|</xsl:for-each>
 </xsl:template>

</xsl:stylesheet>

Given an xml that has many many members that look something like this...

<Product>
    <Brand>Brand</Brand>
    <OldPN>myCompany Part Number</OldPN>    
            ...
</Product>

The output looks like this...

Brand|Brand1|Brand2|Brand3|

Jimmmy 2010-08-17 18:16:07

ansaurus

tags:

views:

answers:

pull unique groups from xml using xslt

related questions