Better way to retry a statement that threw an exception in vb.net

Question

I usually do something like this:

    Dim Attempts = 0
    Try
Retry:
        <Block>
    Catch
        If Attempts < 3 Then
            Attempts += 1
            Thread.Sleep(2000)
            GoTo Retry
        Else
            Throw
        End If
    End Try

This is really bad looking for me, but i don't know of a better way of doing it.

Answer 1

Just use a For loop or a While loop rather than GoTo, breaking on success. But other than that, it's the right approach.

Answer 2

In general, retrying something that failed should be considered very carefully. Usually it is much better to report the error and let the user decide.

Raymond Chen gives a nice example how automatic retries might lead to unwanted problems and gives the advice to avoid retrying:

Take it easy on the automatic retries

Answer 3

I think that's a bad usage, I use this one, and it's much cleaner.

Dim maxAttempt As Integer = 2

For i As Integer = maxAttempt To 0 Step -1

 Try
    ...
    'Successful Quit
    Exit For

  Catch
     Thread.Sleep(2000)

  End Try
Next 

Answer 4

Conceptually it's the right approach, although I would not catch each and every exception, see answer by @0xA3.

You could make it a bit 'prettier' by separating the retry logic from the actual code, e.g.:

    Sub TryExecute(Of T As Exception)(ByVal nofTries As Integer, 
                                      ByVal anAction As Action)
        For i As Integer = 1 To nofTries - 1
            Try
                anAction()
                Return
            Catch ex As T
                Thread.Sleep(2000)
            End Try
        Next
        ' try one more time, throw if it fails
        anAction()
    End Sub

Which could then be used like so:

TryExecute(Of SomeExceptionType)(3, Sub()
                                      <Block>
                                    End Sub())

This will only work in VB 10, if you're using .Net 3.5 / VB 9, you need to separate this in a separate function

Answer 5

You could also try the following:

Dim retryCount as Integer = 0
Dim wasSuccessful as Boolean = False

Do
    Try
        <statements>
        'set wasSuccessful if everything was okay.'
        wasSuccessful = True
    Catch
        retryCount +=1
    End Try
Loop Until wasSuccessful = True OrElse retryCount >=5

'check if the statements were unsuccessful'
If Not wasSuccessful Then
    <do something>
End If

It will retry up to five times if the statements were not successful but will immediately exit the loop if the statements' execution was successful.