How can I parse people's full names into user names in Perl?

Question

I need to convert a name in the format Parisi, Kenneth into the format kparisi.
Does anyone know how to do this in Perl?

Here is some sample data that is abnormal:

Zelleb, Charles F.,,IV
Eilt, John,, IV
Wods, Charles R.,,III
Welkt, Craig P.,,Jr.

These specific names should end up as czelleb, jeilt, cwoods, cwelkt... etc

ADDITION+++++

Thanks for all the good answers! I have one more condition that is ruining my name builder

O'Neil, Paul

so far, Vinko Vrsalovic's answer is working the best when weird/corrupt names are in the mix, but this example above would come out as "pneil"... id be damned below judas if i cant get that o between the p and the n

Answer 1

Try:

$name =~ s/(\w+),\s(\w)/$2$1/;
$name = lc $name;

\w here matches an alphanumerical character. If you want to be more specific, you could also use [a-z] instead, and pass the i flag (case insensitive):

$name =~ s/([a-z]+)\s([a-z])/$2$1/i;

Answer 2

I would start by filtering the abnormal data so you only have regular names. Then something like this should do the trick

$t = "Parisi, Kenneth";
$t =~ s/(.+),\s*(.).*/\l$2\l$1/;

Answer 3

vinko@parrot:~$ cat genlogname.pl

use strict;
use warnings;

my @list;
push @list, "Zelleb, Charles F.,,IV";
push @list, "Eilt, John,, IV";
push @list, "Woods, Charles R.,,III";
push @list, "Welkt, Craig P.,,Jr.";

for my $name (@list) {
        print gen_logname($name)."\n";
}

sub gen_logname {
        my $n = shift;
        #Filter out unneeded characters
        $n =~ s/['-]//g;
        #This regex will grab the lastname a comma, optionally a space (the 
        #optional space is my addition) and the first char of the name, 
        #which seems to satisfy your condition
        $n =~ m/(\w+), ?(.)/;
        return lc($2.$1);
}

vinko@parrot:~$ perl genlogname.pl
czelleb
jeilt
cwoods
cwelkt

Answer 4

Here's a one line solution, assuming you store all the names in a file called "names" (one per line) and you will do duplicated name detection somehow later.

cat names | perl -e 'while(<>) {/^\s*(\S*)?,\s*(\S)/; print lc "$2$1\n";}' | sed s/\'//g

Answer 5

It looks like your input data is comma-separated. To me, the clearest way to do this would be split into components, and then generate the login names from that:

while (<>) {
    chomp;
    my ($last, $first) = split /,/, lc $_;
    $last =~ s/[^a-z]//g;  # strip out nonletters
    $first =~ s/[^a-z]//g; # strip out nonletters
    my $logname = substr($first, 0, 1) . $last;
    print $logname, "\n";
}

Answer 6

 $rowfetch =~ s/['-]//g; #All chars inside the [ ] will be filtered out.
 $rowfetch =~ m/(\w+), ?(.)/;
 $rowfetch = lc($2.$1);

this is how I ended up using Vinko Vrsalovic's solution... its inside a while loop that goes through a sql query result ... thanks again vinko