ansaurus

Question

How can I transform a large discriminated union tree to a readable form?

Answer 1

+3 A:

If you want to write generic union processing code that will not need to list all the union cases, then you'll probably need to use F# reflection API. Here is a simple example.

The formatUnion function uses F# reflection. It assumes that the type parameter 'T is a union type and uses GetUnionFields to get a tuple containing the name of the current case and arguments. It prints the current case name and iterates over all the arguments. If some of the arguments is value of type 'T (meaning that it is recursive union), we recursively print information about the value:

let rec formatUnion indent (value:'T) = //' 
  // Get name and arguments of the current union case
  let info, args = Reflection.FSharpValue.GetUnionFields(value, typeof<'T>) //'
  // Print current name (with some indentation)
  printfn "%s%s" indent info.Name
  for a in args do
    match box a with 
    | :? 'T as v ->  
      // Recursive use of the same union type..
      formatUnion (indent + "  ") v
    | _ -> ()

The following example runs the function on a very simple union value:

type Element = | Nil | And of Element * Element | Or of Element * Element
formatUnion "" (And(Nil, Or(Nil, Nil)))

// Here is the expected output:
// And
//   Nil
//   Or
//     Nil
//     Nil

As a side-note, I think that you could largely simplify your discriminated union by having cases for BinaryOperator and UnaryOperator (with one additional parameter) instead of listing all the element types explicitly. Then you could probably implement the function directly, because it would be quite simple. Something like:

type BinaryOperator = LogicalOr | LogicalAnd | BitwiseOr // ...
type UnaryOperator = Statement | Block | Initializer // ...

type Element = 
  | BinaryOperator of BinaryOperator * Element * Element
  | UnaryOperator of UnaryOperator * Element

Tomas Petricek 2010-09-28 23:54:15

Thanks, it works perfectly. I am gonna look into your suggestion as well.

ChaosPandion 2010-09-29 00:21:42

ansaurus

tags:

views:

answers:

How can I transform a large discriminated union tree to a readable form?

related questions