How can I create arrays and hashes in Perl?

Question

This is not generic question. I have asked this question because I'm confused with creating Perl arrays.

1. How do I create or define the Array or hash? What are other ways to do that?
2. How do I clear a array or hash? What are other ways to do that?
3. How do I create a array or hash with empty element?
4. What are the ways to create hash with out values?

Answer 1

If you're having trouble with basics like this, you should go and have a look at perldoc perlsyn. It covers language syntax and should tell you what you need.

Answer 2

You can create arrays and hashes by assigning lists (including the empty list):

 my @a1; # empty array
 my @a2 = 'a';

 mh %h1; # empty hash
 my %h2 = 'a'; # a => undef
 my %h3 = ('a', 'b'); # 'a' => 'b'
 my %h4 = (a => 'b'); # 'a' => 'b'

You can clear an array or a hash by explicitly assigning an empty list:

 @a2 = ();
 %h3 = ();

Answer 3

It sounds like you could benefit from reading tutorials and beginners guides to Perl. There are numerous examples of doing exactly what you ask.

One thing to keep in mind is that hashes and arrays are pretty much the same (conceptually) but that arrays are indexed by integers and hashes are indexed by strings. Syntactically you reference those indices differently, but conceptually that's how you can think of them.

Answer 4

Create array:

my @array = (1, 2, 3, 4);

Create hash:

my %hash = (
    one   => 1,
    two   => 2,
    three => 2,
    four  => 2,
);

Clear array or hash:

@array = ();
%hash = ();

Create empty array / hash:

my @array = ();
my %hash = ();

Answer 5

Lexical arrays and hashes are created empty. You can create a new lexical array or hash with my:

my @array;
my %hash;

For the most part, you should only be using lexical arrays and hashes, but you can create package arrays and hashes with our:

our @array;
our %hash;

@array and %hash may or may not have data in them in this case (if they were previously created, this will not clear their contents). The names of these variables are lexically scoped, but the data is package scoped, so if you say:

{
    our @a = (1 .. 5);
}
{
    our @a;
    print "@a\n";
}

It will still print "1 2 3 4 5\n".

There are many ways to clear a hash or array. The most common is to assign an empty list to it:

@array = ();
%hash  = ();

You can also use undef to clear a hash or array:

undef @array;
undef %hash;

You could also pop, shift, or splice items off of an array:

pop   @array while @array;
shift @array while @array;

splice @array, 0, scalar @array;

You can also modify the number of elements in and an array by assigning a number to the $#array form of its name. If you assign a negative value, the array is emptied:

$#array = -1;