ansaurus

Question

VB.NET Trying to modify a generic Invoke method to a generic BeginInvoke method, having unexpected problems

Answer 1

+2 A:

It is difficult to use debugging to catch the exception as it will occur on any one of multiple PostMessage calls to the UI message pump (caused by InvokeControl & the BeginInvoke calls). Visual Studio will have a hard time breaking on the exception. This is possibly why it appears that the exception is "magically" being thrown.

Your issue lies not in your implementation of InvokeControl but in the UpdateIndicators method. It is because of the use of the With statement and the asynchronous UI thread calls like this:

With Devices
    ...
    InvokeControl(MillerCurrentIndicator, Sub(x) x.Text = .Miller1.CurrentRead.GetParsedValue.ToString)
    ... 
 End With

Because the Sub(x) code is being executed on the UI thread by posting a message on the UI thread it is extremely likely that the calling code on the current thread will have completed before the UI thread has been executed.

The problem is with the underlying implementation of the Visual Basic With statement. In essence, the compiler creates an anonymous local variable for the With statement that gets set to Nothing at the End With statement.

As an example, if you have this code:

Dim p As New Person
With p
    .Name = "James"
    .Age = 40
End With

The Visual Basic compiler turns this into:

Dim p As New Person
Dim VB$t_ref$L0 As Person = p
VB$t_ref$L0.Name = "James"
VB$t_ref$L0.Age = 40
VB$t_ref$L0 = Nothing

So, in your case, when the UI thread code is executed this anonymous local variable is now Nothing and you get your "Object reference not set to an instance of an object" exception.

Your code essentially is equivalent to this:

Dim VB$t_ref$L0 = Devices
Dim action = new Action(Sub(x) x.Text = VB$t_ref$L0.Miller1.CurrentRead.GetParsedValue.ToString);
VB$t_ref$L0 = Nothing
action(MillerCurrentIndicator);

By the time that the action is called the VB$t_ref$L0 variable is already set to Nothing and whammo!

The answer is not to use a With statement. They are bad.

That should be your answer, but there are a number of other issues in your code though that you should look at too.

Your SyncLock code is using a local locking variable which essentially renders the lock useless. So don't do this:

Private Sub UpdateIndicators()
    Dim ObjLock As New Object
    SyncLock ObjLock
    With Devices
        ...
    End With
    End SyncLock
End Sub

Do this instead:

Private ObjLock As New Object
Private Sub UpdateIndicators()
    SyncLock ObjLock
    With Devices
        ...
    End With
    End SyncLock
End Sub

All of the calls to InvokeControl in the UpdateIndicators method are making it difficult to debug your code. Reducing all of these calls to a single call should help you immensely. Try this instead:

Private Sub UpdateIndicators()
    SyncLock ObjLock
        InvokeControl(Me, AddressOf UpdateIndicators)
    End SyncLock
End Sub

Private Sub UpdateIndicators(ByVal form As ControlInvokeForm)
    With Devices
        EmergencyStopPictureBox.Toggle(Mode > RunMode.NotRunning)
        MillerCurrentIndicator.Text = .Miller1.CurrentRead.GetParsedValue.ToString
        ...
        ToggleImageList(.GateValvePosition.ImageList, .GateValvePosition.SetValue > 0)
    End With
End Sub

Obviously you need to remove the With Devices code to make these work.

There are a number of issues with the following type of code:

If .Ion.GetParsedValue > 0.01 Then
    InvokeControl(IonIndicator, Sub(x) x.Text = "OFF")
Else
    InvokeControl(IonIndicator, Sub(x) x.Text = .Ion.GetParsedValue.ToString)
End If

The value of .Ion.GetParsedValue may have changed between the condition being evaluated and the Else statement being executed. This is compounded because the condition on the If statement is evaluated on the current thread, but the Else statement is executed on the UI thread so the delay could be great. Also, if the .Ion. class is not thread-safe you are exposing yourself to potential errors.

Do this instead:

Dim parsedIonValue = .Ion.GetParsedValue
If parsedIonValue > 0.01 Then
    InvokeControl(IonIndicator, Sub(x) x.Text = "OFF")
Else
    InvokeControl(IonIndicator, Sub(x) x.Text = parsedIonValue.ToString)
End If

(This also gets rid of your With issue.)

Use AutoReset = True on your MasterTimer to automatically call Enabled = False when the event fires to avoid the (remote) possibility of race conditions.

Your code also doesn't seem to be correct in that you are using With Devices in the UpdateIndicators method, but you have a For Each loop in the ReadFromDevices method. Devices then appears to be a collection, but the code in UpdateIndicators is using the Devices object as if it were a Device object. And it is calling .SubstrateBiasVoltage on the Devices object. So I'm not sure exactly what the object Devices is actually doing.

In the ToggleImageList method you are passing the ImageList parameter is being passed ByRef but you are not changing the reference to the ImageList. It's better then to pass it in ByVal to avoid potential bugs.

Also, rather than doing this:

If dev.GetType.Equals(GetType(Miller)) Then
    Dim devAsMiller As Miller = CType(dev, Miller)
    With devAsMiller

It would be cleaner to do this:

Dim devAsMiller = TryCast(dev, Miller)
If devAsMiller IsNot Nothing Then
    With devAsMiller

I hope this doesn't seem like I'm sinking the boot in! Hopefully it is helpful.

Enigmativity 2010-10-08 04:15:31

Ho-ly crap man! This was exactly what I was hoping for. I'm no computer scientist, I've just been trying to figure things out as I went and these things are exactly what I'm scared I don't understand. Things like assuming how the With statement works and being wrong. This must have taken you a while. I really, really appreciate it. I'm going to implement all you suggestions (here and elsewhere in my code). It blows my mind that you'd go through all that effort to help ignorant me. Cheers dude.

BASnappl 2010-10-08 21:56:56

And, to clear up what I was doing with the Devices object: The system for which I'm writing this control program for has about 20 TwinCAT devices, a gate valve controller, and a Pinnacle power-supply. I'm sure this is a dumb way to do this, but basically, I have a class called Device which is inherited by three classes called TwinCatDevice, PinnacleDevice, and GateValveDevice. I then have a class called DeviceList which inherits List(Of Device). Every device is defined as a variable in Devices (a DeviceList object) and is also added to it. So, they can be accessed like Devices.Device or

BASnappl 2010-10-08 22:01:34

(continued) I can loop through the Devices object to access the devices.

BASnappl 2010-10-08 22:02:12

A follow-up question: You suggest calling InvokeControl only once on my main form to do all of the updates. In your suggested code, you have InvokeControl(Me, AddressOf UpdateIndicators) and the UpdateIndicators looks like: Private Sub UpdateIndicators(ByVal form As ControlInvokeForm). Did you mean to have that "ByVal form As ControlInvokeForm" part there? If so, what's it for and what's the ControlInvokeForm class supposed to be? Thanks again!

BASnappl 2010-10-08 22:06:55

Much better. Everything seems to be working now! Thanks a lot Enigmativity.

BASnappl 2010-10-09 07:57:34

@`BASnappl` - Yes, it did take a while to go thru everything, but I do like to be thorough when answering a question. At the end of the day, though, I learn as much answering questions as I hope you do in getting the answer. The `InvokeControl(Me, AddressOf UpdateIndicators)` requires the method `Private Sub UpdateIndicators(ByVal form As ControlInvokeForm)` for the call to work. It's there to allow the `BeginInvoke` to be called on the form. `ControlInvokeForm` was the name of the form I used in my testing of the answer.

Enigmativity 2010-10-12 06:38:20

ansaurus

tags:

views:

answers:

VB.NET Trying to modify a generic Invoke method to a generic BeginInvoke method, having unexpected problems

related questions