ansaurus

Question

xsltproc doesn't select elements by name

Answer 1

+2 A:

The html element in your source XML defines a namespace. You have to include it in your match expression and reference it in your xsl:stylesheet element:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:html="http://www.w3.org/1999/xhtml"&gt;
    <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>
    <xsl:template match="/">
        <xsl:text>---[</xsl:text>
        <xsl:for-each select="html:html">
            <xsl:text>Found HTML element.</xsl:text>
        </xsl:for-each>
        <xsl:text>]---</xsl:text>
    </xsl:template>
</xsl:stylesheet>

Frédéric Hamidi 2010-10-17 18:52:16

If I do that, I get "XPath error : Undefined namespace prefix". Do I need to add something to the stylesheet to say how to resolve the namespace?

Tadmas 2010-10-17 18:57:46

The HTML namespace will need to be declared in the stylesheet as well. Typically, on the document element of the stylesheet: `<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:html="http://www.w3.org/1999/xhtml">`, but it can also be declared on the for-each element: `<xsl:for-each select="html:html" xmlns:html="http://www.w3.org/1999/xhtml">`

Mads Hansen 2010-10-17 19:02:26

Sorry, forgot the namespace reference in the `xsl:stylesheet` element. I updated my answer.

Frédéric Hamidi 2010-10-17 19:04:06

Works beautifully. Wish I could omit typing that namespace, though, since more complex XPath expressions like html:html/html:body/html:div[@id='foo']/... is going to get really hard to read. Sigh... at least it works now. :)

Tadmas 2010-10-17 19:07:10

Answer 2

+1 A:

Change your stylesheet from:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt; 
    <xsl:output method="text" omit-xml-declaration="yes" indent="no"/> 
    <xsl:template match="/"> 
        <xsl:text>---[</xsl:text> 
        <xsl:for-each select="html"> 
            <xsl:text>Found HTML element.</xsl:text> 
        </xsl:for-each> 
        <xsl:text>]---</xsl:text> 
    </xsl:template> 
</xsl:stylesheet>

to:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:x="http://www.w3.org/1999/xhtml"
> 
    <xsl:output method="text" omit-xml-declaration="yes" indent="no"/> 
    <xsl:template match="/"> 
        <xsl:text>---[</xsl:text> 
        <xsl:for-each select="x:html"> 
            <xsl:text>Found HTML element.</xsl:text> 
        </xsl:for-each> 
        <xsl:text>]---</xsl:text> 
    </xsl:template> 
</xsl:stylesheet>

Explanation:

The XML document has declared a default namespace: "http://www.w3.org/1999/xhtml", and all unprefixed nodes that descend from the top element declaring this default namespace, belong to this namespace.

On the other side, in XPath any unprefixed name is considered to belong in "no namespace".

Therefore, the <xsl:for-each select="html"> instruction will select and apply its body to all html elements that belong to "no namespace" -- and there are none such in the document -- the only html element does belong to the xhtml namespace.

Solution:

The the names that belong to a default namespace cannot be referenced unprefixed. Therefore, we need to bind a prefix to the namespace such an element belongs to. If this prefix is "x:", then we can reference any such element prefixed with "x:".

Dimitre Novatchev 2010-10-17 19:01:09

ansaurus

tags:

views:

answers:

xsltproc doesn't select elements by name

related questions