Converting plain text into html style lists using xstl, or grouping elements according to their contents and their positions using xslt

Question

Trying to convert a plain text document into a html document using xslt, I am struggling with unordered lists.

I have:

<item>some text</item>
<item>- a list item</item>
<item>- another list item</item>
<item>more plain text</item>
<item>more and more plain text</item>
<item>- yet another list item</item>
<item>even more plain text</item>

What I want:

<p>some text</p>
<ul>
    <li>a list item</li>
    <li>another list item</li>
</ul>
<p>more plain text</p>
<p>more and more plain text</p>
<ul>
    <li>yet another list item</li>
</ul>
<p>even more plain text</p>

I was looking at the Muenchian grouping but it would combine all list items into one group and all the plain text items into another. Then I tried to do select only items which preceding elements first char is different from its first char. But when I try to combine everything, I still get all the li in one ul.

Do you have any hints for me?

Answer 1

This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kFollowing"
   match="item[contains(., 'list')]
          [preceding-sibling::item[1][contains(.,'list')]]"
   use="generate-id(preceding-sibling::item
                      [not(contains(.,'list'))]
                      [1]
                        /following-sibling::item[1]
                      )"/>

 <xsl:template match="item[contains(.,'list')]
              [preceding-sibling::item[1][not(contains(.,'list'))]]">

  <ul>
   <xsl:apply-templates mode="list"
        select=".|key('kFollowing',generate-id())"/>
  </ul>
 </xsl:template>

 <xsl:template match="item" mode="list">
  <li><xsl:value-of select="."/></li>
 </xsl:template>

 <xsl:template match="item[not(contains(.,'list'))]">
  <p><xsl:value-of select="."/></p>
 </xsl:template>

 <xsl:template match="item[contains(.,'list')]
              [preceding-sibling::item[1][contains(.,'list')]]"/>
</xsl:stylesheet>

when applied on the provided XML document (corrected from severely malformed into a well-formed XML document):

<t>
 <item>some text</item>
 <item>- a list item</item>
 <item>- another list item</item>
 <item>more plain text</item>
 <item>more and more plain text</item>
 <item>- yet another list item</item>
 <item>even more plain text</item>
</t>

produces the wanted, correct result:

<p>some text</p>
<ul>
   <li>- a list item</li>
   <li>- another list item</li>
</ul>
<p>more plain text</p>
<p>more and more plain text</p>
<ul>
   <li>- yet another list item</li>
</ul>
<p>even more plain text</p>

Answer 2

This stylesheet:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="node()">
        <xsl:apply-templates select="node()[1]|following-sibling::node()[1]"/>
    </xsl:template>
    <xsl:template match="item">
        <p>
            <xsl:value-of select="."/>
        </p>
        <xsl:apply-templates select="following-sibling::node()[1]"/>
    </xsl:template>
    <xsl:template match="item[starts-with(.,'- ')]">
        <ul>
            <xsl:call-template name="open"/>
        </ul>
        <xsl:apply-templates
             select="following-sibling::node()
                        [not(self::item[starts-with(.,'- ')])][1]"/>
    </xsl:template>
    <xsl:template match="node()" mode="open"/>
    <xsl:template match="item[starts-with(.,'- ')]" mode="open" name="open">
        <li>
            <xsl:value-of select="substring-after(.,'- ')"/>
        </li>
        <xsl:apply-templates select="following-sibling::node()[1]" mode="open"/>
    </xsl:template>
</xsl:stylesheet>

Output:

<p>some text</p>
<ul>
    <li>a list item</li>
    <li>another list item</li>
</ul>
<p>more plain text</p>
<p>more and more plain text</p>
<ul>
    <li>yet another list item</li>
</ul>
<p>even more plain text</p>

Note: This is like wrapping adjacents. Ussing fine grained traversal.