tags:

views:

769

answers:

2
Q: 

How can I prevent these redundant namespaces from an XSLT stylesheet?

When using an XSLT stylesheet to transform an XML file which contains embedded XHTML (using namespaces) into pure XHTML, I'm left with redundant namespace definitions on the elements which were originally XHTML. Simple test case:

XML:

<?xml version="1.0" encoding="utf-8" ?>
<?xml-stylesheet type="text/xml" href="fbb.xsl"?>
<foo xmlns="urn:foo:bar:baz" xmlns:html="http://www.w3.org/1999/xhtml"&gt;
    <bar>
        <baz>Some <html:i>example</html:i> text.</baz>
    </bar>
</foo>

XSL:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet version="1.0" xmlns="http://www.w3.org/1999/xhtml" xmlns:fbb="urn:foo:bar:baz" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="fbb">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/fbb:foo">
        <html>
            <head>
                <title>Example</title>
            </head>

            <body>
                <p>
                    <xsl:copy-of select="fbb:bar/fbb:baz/node()"/>
                </p>
            </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

Output:

<?xml version="1.0"?>
<html xmlns="http://www.w3.org/1999/xhtml"&gt;
  <head>
    <title>Example</title>
  </head>
  <body>
    <p>Some <html:i xmlns="urn:foo:bar:baz" xmlns:html="http://www.w3.org/1999/xhtml"&gt;example&lt;/html:i&gt; text.</p>
  </body>
</html>

Is it possible to prevent the redundant namespaces (and prefix) from being added to the <i> element? (For reference, I'm using xsltproc with libxml2-2.7.3 and libxslt-1.1.24 on Cygwin.)

A: 

Update your exclude-result-prefixes to include the default namespace:

exclude-result-prefixes="#default"

Or you could suppress all inline namespacing by doing:

exclude-result-prefixes="#all"

There is a bit of wonkiness though, as some processors expect a space-separated list while others expect a comma-separated list. xsltproc seems to like comma-separated so if you still want to be explicit you can do:

exclude-result-prefixes="#default,fbb"
johnvey  2009-05-06 03:59:40
Hmm… my copy of xsltproc actually gives an "undefined namespace" error for comma-separated lists. A space-separated list including "#default" doesn't seem to change its behavior, and including "#all" again produces "undefined namespace".
Ben Blank  2009-05-06 16:30:59
libxslt only supports XSLT 1.0 and #default and #all are XSLT 2.0.
jelovirt  2009-05-06 18:16:03
+1  A: 

Instead of xsl:copy-of use an identity transformation templates and remove the namespace prefix from XHTML elements.

<xsl:stylesheet version="1.0"
                xmlns="http://www.w3.org/1999/xhtml"
                xmlns:fbb="urn:foo:bar:baz"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:html="http://www.w3.org/1999/xhtml"
                exclude-result-prefixes="fbb html">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/fbb:foo">
    <html>
      <head>
        <title>Example</title>
      </head>
      <body>
        <p>
          <xsl:apply-templates select="fbb:bar/fbb:baz/node()"/>
        </p>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="html:*">
    <xsl:element name="{local-name()}">
      <xsl:apply-templates select="@* | node()"/>
    </xsl:element>
  </xsl:template>

  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>
jelovirt  2009-05-06 18:22:48

related questions

xslt and xpath: match conditionally upon current node value
How can I make an exact copy of a xml node's children with XSLT?
How to escape XML content with XSL to safely output it as JSON?
How do I convert a .docx to html using asp.net?
Using XSLT, How Do You Insert XML Into an existing XML node
How can I lay images out in a grid using XSL-FO?
How to validate an XML file against a schema using Visual Studio 2005
What is a good resource for learning XSL?
xslt: apply-templates in reverse order
How do you add an image in XSLT?
If you were programming a calendar in HTML would you use Table tags or Div tags?
How to Convert a StreamReader into an XMLReader object in .Net 2.0/C#
Can I create a value for a missing tag in XPath?
ASP.NET MVC vs. XSL
How to apply an XSLT Stylesheet in C#
XSLT dividing a list of nodes in half
XSLT nodesets Length
using a html entity in xslt (e.g. &nbsp;)
XSLT Find and Replace with Unique
XSL Dynamic Element Names
XSLT - Reverse Find in a string
VS2008 SP1 crashes when debugging an XSLT file
Is it "bad practice" to be sensitive to linebreaks in XML documents?
How do you use a variable in xsl when trying to select a node?
.Net XML comment into API Documentation