Is there a plugin for listing subversion tags in Hudson?

Question

In Hudson we have a job that deploys a specified subversion tag to a server. This tag is currently entered in a text field, but since that is just a typing mistake waiting to happen, we would like that text field to be replaced by a drop down list with the currently available tags. That is, we would like Hudson to go to <subversion repo url>/tags and fetch all tags found there.

I've searched for a Hudson plugin or some other way to accomplish this, with no success. This can't be the first time someone wants this, right? Or would this be considered bad practice for some reason that I can not think of at the moment?

EDIT

Someone else did have the same idea (only three weeks ago), but there is no posted solution right now: http://issues.hudson-ci.org/browse/HUDSON-6682?page=com.atlassian.jira.plugin.system.issuetabpanels%3Aall-tabpanel

Answer 1

How about the batch task Plugin. This will allow you to go to any build in Hudson (current and old one) and run a batch on that build. The batches are predefined tasks.

This will only work for your purpose if Hudson is creating you official build and tagging it in subversion. And of course only for the builds that are not deleted yet. ;)

Answer 2

Hello Peter,

In lieu of a Hudson plug-in (I do not know Java), how about some XSL (1.0)? In the following solution :

1. We get a directory list of tags via svn list --xml, saved to svn-list.xml
2. We run a transform to turn svn-list.xml into Hudson's internal schema for a choice drop-down, saved to hudson-list.xml
3. We run another transform to join hudson-list.xml into the job's config.xml based on a specific name for the list we want to update, saved to new-config.xml, and update the Hudson job with the new config

1. svn list --xml

  svn list [path-to-svn-tag-directory] --xml > svn-list.xml

2. Convert SVN list to Hudson list

  xsltproc svn-to-hudson.xsl svn-list.xml > hudson-list.xml

svn-to-hudson.xsl:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="/lists/list">
    <hudson.model.ChoiceParameterDefinition>
      <name>[Your Name for the List]</name>
      <description/>
      <choices class="java.util.Arrays$ArrayList">
        <a class="string-array">
          <xsl:apply-templates select="entry"/>
        </a>
      </choices>
    </hudson.model.ChoiceParameterDefinition>
  </xsl:template>

  <xsl:template match="entry">
    <string>
      <xsl:value-of select="name"/>
    </string>
  </xsl:template>
</xsl:stylesheet>

3. Join Hudson List with Job's config.xml

The following uses curl to get fetch the old config.xml, and to post the new one, utilizing Hudson's job API for modifying the config.

curl -o old-config.xml http://[your-hudson-server]/job/[job-name]/config.xml -u [username]:[password]
xsltproc join.xsl old-config.xml > new-config.xml
curl -X POST -d @new-config.xml http://[your-hudson-server]/job/[job-name]/config.xml -u [username]:[password]

join.xsl requires the presence of hudson-list.xml in the same directory:

<xsl:variable name="tag-list" select="document('hudson-list.xml')"/>

You will also need to modify

<xsl:variable name="list-name" select="string('Name')"/>

to the name of your list in the job (e.g., 'SVN tags', 'Tagged Builds', etc...).

join.xsl:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
  <xsl:output method="xml" indent="yes"/>

  <xsl:variable name="tag-list" select="document('hudson-list.xml')"/>
  <xsl:variable name="list-name" select="string('Name')"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="hudson.model.ChoiceParameterDefinition">
    <xsl:choose>
      <xsl:when test="name = $list-name"> <!-- If the name matches, swap in new list -->
        <xsl:copy-of select="$tag-list"/>
      </xsl:when>
      <xsl:otherwise>                      <!-- If the name does not match, copy what's already there -->
        <xsl:copy-of select="."/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

I hope this end-to-end solution works for you.

Thank you,
Zachary