Perl regex: How to grab the part that is the same

Question

Hi! I'm creating a ladder system for some games and I've encountered a problem regarding the clan base system. You see, every player who joins are parsed and put into a players table. Like this:

chelsea | gordon 
chelsea | jim
chelsea | brad

OR...

CLANTAG|> jenna
CLANTAG|> jackson
CLANTAG|> irene

So, what I want: I wanna grab the CLANTAG, which is at the same place and identical in every players name, which are on that team. But, the separator could be anything from whitespace to nothing (clan player1, clan player2 OR clanplayer1, clanplayer2).

Any ideas on how to do this?

Thanks in advance.

Answer 1

Taking a wild stab here, is this what you want?

#! /usr/bin/perl

use strict;
use warnings;

while (<DATA>)
{
  if (/^(\w+) \| (\w+)$/     ||
      /^\[(\w+)\] \. (\w+)$/ ||
      /^(\w+)-(\w+)$/)
  {
    print "tag=$1, name=$2\n";
  }
}

exit 0;

__DATA__
team1 | foo
team1 | bar

[another] . user
[another] . player

more-james
more-brown

Because it generates:

tag=team1, name=foo
tag=team1, name=bar
tag=another, name=user
tag=another, name=player
tag=more, name=james
tag=more, name=brown

Answer 2

Edit: re-read question and comments..

This works for the example, but may not work for names with spaces or punctuation, and possibly other scenarios:

while ( <DATA> )
{
    if ( /(\w+).*?(\w+)$/ )
    {
        print "$1, $2\n";
    }
}


__DATA__
team1 | foo
team1 | bar

[another] . user
[another] . player

more-james
more-brown

Gives:

team1, foo
team1, bar
another, user
another, player
more, james
more, brown

Answer 3

If you're just running the regex on one player's name at a time, I would suggest:

/(\w+)\W+(\w+)$/

In English, this means "at least one word character, followed by at least one non-word character, followed by at least one word character, and then the end of the line"

"Word character" is letters, numbers, and underscores. So if people ever use anything other than those characters in their tags/nicks, it'll need modification. For example, if people might also have hyphens in their nicks you'd need:

/(\w+)\W+([\w-]+)$/

As far as I know, people always use punctuation-type characters (and/or whitespace) for the separation between their clan and their nick, so the \W+ there should be fine.

As for the case you gave with no separator (clanplayer1, clanplayer2), there's no way to solve this without looking at multiple players' names that you know are in the same clan, and figuring out at which point their names start to differ, so it can't be solved with a regex alone.

Answer 4

Here's a shot:

use strict;
use warnings;

my($strip) = shift || 0;

print FindTeamName("TEAMJimBob", "TEAMJoeBob", "TEAMBillyBob"), "\n";
print FindTeamName("TEAM|JimBob", "TEAM|JoeBob", "TEAM|BillyBob"), "\n";
print FindTeamName("TEAM | JimBob", "TEAM | JoeBob", "TEAM | BillyBob"), "\n";
print FindTeamName("TEAMJimBob", "TEAM|JoeBob", "TEAM - BillyBob"), "\n";

sub FindTeamName
{
    my(@players) = @_;

    my($team) = shift;
    foreach my $player (@players) {
     $team = FindCommonString($team, $player);
    }

    $team =~ s{\W+$}{} if $strip;

    $team;
}

sub FindCommonString
{
    my($str1, $str2) = @_;

    my(@arr1) = split(//, $str1);
    my(@arr2) = split(//, $str2);

    my($common) = "";

    while (@arr1 && @arr2) {
     my($letter1) = shift(@arr1);
     my($letter2) = shift(@arr2);

     if ($letter1 eq $letter2) {
      $common .= $letter1;
     }
     else {
      last;
     }
    }

    $common;
}

which gives the following:

C:\temp>perl test.pl
TEAM
TEAM|
TEAM |
TEAM

C:\temp>perl test.pl 1
TEAM
TEAM
TEAM
TEAM

C:\temp>