How can I keep only the first five lines in a Perl scalar?

Question

From any kind of scalar, what regex could I use to match the first five lines of it and discard the rest?

Answer 1

Why don't you just use head for that?

Answer 2

Odd request, but this should do it:

#!/usr/bin/perl

use strict;
use warnings;

my $s = join '', map { "$_\n" } 1 .. 9;

my ($first) = $s =~ /^((?:.*\n){0,5})/;
my ($last) = $s =~ /((?:.*\n){0,5})$/;


print "first:\n${first}last:\n$last";

A more common solution would be something like this:

#!/usr/bn/perl

use strict;
use warnings;

#fake a file for the example    
my $s = join '', map { "$_\n" } 1 .. 9;    
open my $fh, "<", \$s
    or die "could not open in memory file: $!";

my @first;
while (my $line = <$fh>) {
    push @first, $line;
    last if $. == 5;
}

#rewind the file just in case the file has fewer than 10 lines
seek $fh, 0, 0;

my @last;
while (my $line = <$fh>) {
    push @last, $line;
    #remove the earliest line if we have to many
    shift @last if @last == 6;
}

print "first:\n", @first, "last:\n", @last;

Answer 3

my ($first_five) = $s =~ /\A((?:.*\n){5})/;
my ($last_five) = $s =~ /((?:.*\n){5})\z/;

Answer 4

As Brian says, you can use head or tail pretty easily for either problem (first 5 lines or last 5 lines).

But now I'm wondering if I even understand your question correctly. When you say "for any kind of scalar", do you mean that (for whatever reason) the file is already in a scalar?

If not, I think that the best solution is no regex at all. Use $. and either read the file normally or backwards. To read backwards, you can try File::ReadBackwards or File::Bidirectional.

Answer 5

People are missing some key flags:

/(?m)((?:^.*\n?){1,5})/

Without the multi-line flag, it's only going to look at the first line. Also by making the \n optional, we can take the first five lines, regardless of a newline at the end of the fifth.

Answer 6

You don't need a regex. Just open a filehandle on a reference to the scalar then do the same things that you would for any other sort of filehandle:

my $scalar = ...;

open my($fh), "<", \ $scalar or die "Could not open filehandle: $!";
foreach ( 1 .. 5 )
    {
    push @lines, scalar <$fh>;
    }
close $fh;

$scalar = join '', @lines;

Answer 7

Why not just use split with a limit, it's designed for this purpose:

my @lines = (split /\n/, $scalar, 6)[0..4];

If you want that back as a single scalar with five lines, join it back up:

my $scalar = join('\n', @lines) . "\n";

Answer 8

use strict;


my $line; #Store line currently being read
my $count=$ARGV[1]; # How many lines to read as passed from command line
my @last; #Array to store last count lines
my $index; #Index of the line being stored


#Open the file to read as supplied from command line
open (FILE,$ARGV[0]);
while ($line=<FILE>)
{
    $index=$.%$count;  # would help me in filter just $count records of the file
    $last[$index]=$line; #store this value
}
close (FILE);

#Output the stored lines
for (my $i=$index+1;$i<$count;$i++)
{
    print ("$last[$i]");
}
for (my $i=$0;$i<=$index;$i++)
{
    print ("$last[$i]");
}