How can I extract abbreviations from a file using Perl?

Question

I need to extract certain Abbreviations from a file such as ABS,TVS,and PERL. Any abbreviations which are in uppercase letters. I'd preferably like to do this with a regular expression. Any help is appreciated.

Answer 1

Untested:

my %abbr;
open (my $input, "<", "filename")
  || die "open: $!";
for ( < $input > ) {
  while (s/([A-Z][A-Z]+)//) {
    $abbr{$1}++;
  }
}

Modified it to look for at least two consecutive capital letters.

Answer 2

It would have been nice to hear what part you were particularly having trouble with.

my %abbr;
open my $inputfh, '<', 'filename'
    or die "open error: $!\n";
while ( my $line = readline($inputfh) ) {
    while ( $line =~ /\b([A-Z]{2,})\b/g ) {
        $abbr{$1}++;
    }
}

for my $abbr ( sort keys %abbr ) {
    print "Found $abbr $abbr{$abbr} time(s)\n";
}

Answer 3

#!/usr/bin/perl

use strict;
use warnings;

my %abbrs = ();

while(<>){
    my @words = split ' ', $_;

    foreach my $word(@words){
        $word =~ /([A-Z]{2,})/ && $abbrs{$1}++;
    }
}

# %abbrs now contains all abreviations

Answer 4

Reading text to be searched from standard input and writing all abbreviations found to standard output, separated by spaces:

my $text;
# Slurp all text
{ local $/ = undef; $text = <>; }
# Extract all sequences of 2 or more uppercase characters
my @abbrevs = $text =~ /\b([[:upper:]]{2,})\b/g;
# Output separated by spaces
print join(" ", @abbrevs), "\n";

Note the use of the POSIX character class [:upper:], which will match all uppercase characters, not just English ones (A-Z).