Why does map return an empty array?

Question

I have a problem in Perl I don't understand. I stripped it down to this very short code.

Why does Perl's map function return an empty array? Shouldn't it return an array with 9 undefs?

sub mySub{
    return;
}

my @arr = (1 .. 9);
my @arr2 = map( mySub($_), @arr );

print @arr . ' ' . @arr2, "\n";

It prints "9 0".

It is probably something simple, but perldoc is not helping.

Answer 1

You subroutine is not returning undef, it is returning an empty list. 9 times and empty list is still an empty list.

Try explicitly returning undef and the output will be different.

Answer 2

Try this

use strict;
use warnings;

sub mySub{
    return undef;
}

my @arr = (1,2,3,4,5,6,7,8,9);
my @arr2 = map(&mySub, @arr);

print @arr." ".@arr2;

If you need to get list containing undefs, you need to return undef explicitly. The thing is that map calls your mySub in array context (check what wantarray gives you from this sub). return statement essentially gives back an empty list each time your sub is called, which results in empty array in total

Answer 3

The more general answer to your question is this: when return is used without an argument, the value it returns depends on the calling context:

list context    returns an empty list
scalar context  returns an undefined value

For example:

use strict;
use warnings;
use Data::Dumper;

my (@list);
sub mySub { return }
@list = map(       mySub($_), 1..2); print Dumper(\@list);
@list = map(scalar mySub($_), 1..2); print Dumper(\@list);

Output:

$VAR1 = [];
$VAR1 = [
          undef,
          undef
        ];