How can I perform an operation based on the previous read line in Perl?

Question

Hi,

I am still learning Perl scripting and need help in doing below task.

Sample data:


INV ,GOOD"
2405
INV ,BAD"
42
LOAD ,GOOD"
35588
LOAD ,BAD"
675
TRNS ,GOOD"
6
TRNS ,BAD"
122

I want to add the values under GOOD and BAD.

GOOD, <sum of all good values>
BAD, <sum of all bad values>

Can anyone please suggest me code to read the first line and put the values from next line in an array to add them latter.

Answer 1

It could be something like this:

while (<>)
{
  $good += <> if (m/GOOD/);
  $bad += <> if (m/BAD/)
}

print "GOOD: $good";
print "BAD: $bad";

This just sums the values as you go along and prints them out, rather than accumulating them in an array. It wouldn't be too hard to change it to store the intermediate values though.

Answer 2

 use strict;                                     
 use warnings;                                   

 use Data::Dumper;                               

 my %to_sum;                                     
 while (<DATA>) {                                
     /,(GOOD|BAD)"$/;
     next unless $1;                            
     push @{ $to_sum{$1} ||= [] }, scalar <DATA>;
 }                                               
 chomp @$_ for values %to_sum;                   
 print Dumper \%to_sum;                          

 __DATA__                                        
 INV ,GOOD"                                      
 2405                                            
 INV ,BAD"                                       
 42                                              
 LOAD ,GOOD"                                     
 35588                                           
 LOAD ,BAD"                                      
 675                                             
 PIN ,GOOD"                                      
 6                                               
 TRNS ,BAD"                                      
 122

Gives you

 $VAR1 = {                     
           'BAD' => [          
                      '42',    
                      '675',   
                      '122'    
                    ],         
           'GOOD' => [         
                       '2405', 
                       '35588',
                       '6'     
                     ]         
         };

Answer 3

The following puts the numbers in arrays. The parsing will be tolerant for blank lines or other input, it will wait for GOOD or BAD and then use the number from the next line.

#!/usr/bin/perl -w
use strict;
use warnings;

my $state = 0;
my $state_good = 1;
my $state_bad  = 2;
my @goods = ();
my @bads = ();


while (my $line = <>) {
        chomp($line);

        if ($line =~ /GOOD/) {
                $state = $state_good;
                next;
        }
        if ($line =~ /BAD/) {
                $state = $state_bad;
                next;
        }
        next if $state == 0;

        if ($state == $state_good) {
                push @goods, $line;
                $state = 0;
        }
        if ($state == $state_bad) {
                push @bads, $line;
                $state = 0;
        }
}


print "sum good: ", sum(@goods), "\n";
print "sum bad:  ", sum(@bads),  "\n";

sub sum {
        my $ret = 0;
        while (@_) {
                my $n = shift;
                $ret += $n;
        }
        return $ret;
}

Answer 4

#!/usr/bin/perl

use strict;
use warnings;

my $bad = 0;
my $good = 0;
while (<>) {
    if ( /,GOOD"$/ ... /^(\d+)$/ ) {
        $good += $1 if defined($1);
    }
    if ( /,BAD"$/ ... /^(\d+)$/ ) {
        $bad += $1 if defined($1);
    }
}

print "GOOD, $good\n";
print "BAD, $bad\n";

Using the range operator in scalar context is explained in man perlop (Range Operator), and it's quite cool. Got the answer from the Perl Cookbook, recipe 6.8.