Why can't I use an expression to build a class name in Perl's require?

Question

Hi Guys,

Suppose the module AAA::BBB::CCC located in ~/modules/AAA/BBB/CCC.pm, and "~/modules" is in @INC, so why the following code doesn't work and lead to compile error?

$class = "AAA::BBB" ;
$type = "CCC";
require $class . '::' . $type ;

I try to use require AAA::BBB::CCC instead, it works . If I do need dynamically require a module by combining strings together rather than hardcode the module name directly, how should I do ?

thanks

Answer 1

From perldoc -f require:

But if you try this:

$class = 'Foo::Bar';
require $class; # $class is not a bareword
#or
require "Foo::Bar"; # not a bareword because of the ""

The require function will look for the "Foo::Bar" file in the @INC array and will complain about not finding "Foo::Bar" there. In this case you can do:

eval "require $class";

Therefore, you can try this instead:

$class = "AAA::BBB";
$type = "CCC";
eval qq{ require "${class}::${type}" };

Answer 2

My approach:

my $class = "AAA::BBB";
my $type = "CCC";

my $full_class_name = $class . '::' . $type;
( my $file_name = $full_class_name . '.pm' ) =~ s{::}{/}g;

require $file_name;

$full_class_name->test();

Using eval, if you're only doing "die $@ if $@" doesn't make much sense - without eval it will work just as fine.

This additional step of making file_name, and requiring $file_name instead of class makes it not required to use string based eval, which tends to be rather slow.

Of course you still can use eval if you want to provide some kind of fallback:

eval { require $file_name };
if ( my $error = $@ ) {
    ... do something ...
}

But note, that this is block-based eval, and not a string-based one.

Answer 3

If I may restate your symptoms, I assume you mean this fails like so:

require "AAA::BBB" . "::" . "CCC"; # built from $class and $type;
# => Can't locate AAA::BBB::CCC in @INC (@INC contains ...

because it cannot find a file named AAA::BBB::CCC. However, this succeeds:

require AAA::BBB::CCC;  # note, this is _not_ quoted

because perl searches for a subdirectory-nested module named, in part, AAA/BBB/CCC.pm.

This is how require works. From the documentation for require EXPR:

If EXPR is a bareword, the require assumes a ".pm" extension and replaces "::" with "/" in the filename for you, to make it easy to load standard modules.

So, you must generally either convert your constructed module name to a pathname fragment (s!::!/!g appending ".pm"), or string eval your constructed module name, as others have suggested.

Answer 4

suppose the module AAA::BBB::CCC.pm located in ~/modules/AAA/BBB/CCC.pm

There is no such thing as AAA::BBB::CCC.pm. There is only AAA/BBB/CCC.pm and is AAA::BBB::CCC.

Don't confuse package names and module files.

Answer 5

I have this kludgy utility class defined in my current project:

package Util::RequireClass;

use strict;
use warnings;

use Exporter 'import'; # gives you Exporter's import() method directly
our @EXPORT_OK = qw(requireClass);

sub requireClass
{
    my $class = shift;
    eval "require $class" or do { die "Ack, can't load $class: $@" };
}

1;