Is 999...9 a real number in Perl?

Question

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}

sub is_float {
   defined $_[0] && $_[0] =~ /^[+-]?\d+(\.\d+)?$/;
}

For the code mentioned above, if we give input as 999999999999999999999999999999999999999999, it is giving output as not real number.

Can anyone help me in this regard why it is behaving like that?

I forgot to mention one more thing :

if i am using this code for $x as above value

if($x > 0 || $x <= 0 ) { print "Real"; }

output is real.

how is it possible? can anyone explain???

Answer 1

$ perl -e 'print 999999999999999999999999999999999999999999'
1e+42

i.e. Perl uses scientific representation for this number and that is why your regexp doesn't match.

Answer 2

Just to add one more thing. As others have explained, the number you are working with is out of range for a Perl integer (unless you are on a 140 bit machine). Therefore, the variable will be stored as a floating point number. Regular expressions operate on strings. Therefore, the number is converted to its string representation before the regular expression operates on it.

Answer 3

Have a look at using looks_like_number function from Scalar::Util (a core module).

use Scalar::Util qw( looks_like_number );

say "Number" if looks_like_number 999999999999999999999999999999999999999999;

# above prints "Number"

/I3az/

Answer 4

Also, you may want to take a look at bignum in the Perl documentation.

Answer 5

Others have explained what is going on: out of the box, Perl can't handle numbers that large without using scientific notation.

If you need to work with large numbers, take a look at bignum or its components, such as Math::BigInt. For example:

use strict;
use warnings;
use Math::BigInt;

my $big_str = '900000000000000000000000000000000000000';
my $big_num = Math::BigInt->new($big_str);

$big_num ++;
print "Is integer: $big_num\n" if is_integer($big_num);

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}