How can I ask the user to re-enter input when they enter invalid input, in Perl?

Question

Hi,

I've a Perl subroutine which asks input from User. I perform a check inside that subroutine itself whether the input entered is a valid input.

If it's not, I want to call the subroutine again to let the user enter a valid input this time.

My subroutine is as follows:

sub some_routine {    
    print "Enter a number to select   (1) Apple (2) Mango (3) grapes:"
    $value=STDIN;
    if($value =~ /[^1-3]/ ) {
        print "The input is not valid!";
        print "Do you want to continue selecting a fruit again (Y or N)?";
        $choice = STDIN;
        if( $choice eq "y") {
            ### I want to call the subroutine again to enter input ###
          } else {
            exit;
        }
    }
}

So how to recurse a subroutine in this?

Answer 1

EDIT: For a variety of reasons (style, performance, etc...), I would strongly advise not do a recursive call here, though, but rather check it in a while loop.

[Original answerer's disclaimer] "From a style perspective, I would not do a recursive call here, though, but rather check it in a while loop, but I guess to a degree, that's a matter of taste as well."

As far as using recursion, as an example, you can just call the function from within the function, like so:

sub get_positive_number {
    print "Please enter a positive number: ";
    my $number = <STDIN>;
    chomp $number;
    if ($number > 0) {
        return $number;
    }
    else {
        return get_positive_number();
    }
}

my $result = get_positive_number();
print "result: $result\n";

Answer 2

There's no reason to use recursion for this. A simple while loop will do.

my $input_valid = 0;
while( !$input_valid ) { 
    print "Enter some input: ";
    my $input = <STDIN>;
    $input_valid = validate_input( $input );
}

If validate_input returns 0, the loop will repeat.

Answer 3

To call a subroutine recursively in Perl, you just call the sub from itself, the same as in any other language:

sub factorial {
  my $num = shift;
  return 1 if $num < 2;
  return $num * factorial($num - 1);
}

However, you don't really want to use recursion for a "repeat until condition changes" scenario.
That's what while loops are for:

my $valid;
while (!$valid) {
  print "Enter something: ";
  my $data = <STDIN>;
  $valid = validate($data);
  print "Bzzt!  Invalid - try again!\n" unless $valid;
}

Answer 4

my $value;
until(defined $value = get_value()) {
  print"you didn't enter a valid value\n";
}

sub get_value {
 print "Enter a number to select   (1) Apple (2) Mango (3) grapes:"
    $value=<STDIN>;
    if($value =~ /[1-3]/ ) {
        return $value;
    } else {
        return undef;     
    }
}

Answer 5

The correct way to call the routine is

goto &some_routine;

...because what you have is a tail call - it's the last thing you do in your function. If you call it normally you eat a stack frame for each call and memory allocation goes up. Called like this, you re-use the same stack frame. From your perspective as a programmer, this is the same as

return some_routine(@_);

but without eating memory.

This only works for routines that call themselves as the last thing they do - in other cases, you should indeed be switching to the while loop that other people suggest (and, for code attractiveness, you may want to do that anyway).

Answer 6

recursive

sub select_fruit {    
    print "Enter a number to select   (1) Apple (2) Mango (3) grapes:"
    $value=<STDIN>;
    if($value =~ /[^1-3]/ ) {
        print "The input is not valid!";
        print "Do you want to continue selecting a fruit again (Y or N)?";
        $choice = <STDIN>;
        if( $choice eq "y") {
            $value = select_fruit();
          } else {
            exit;
        }
    }
    return $value;
}

goto - Tail Call Optimization (TCO)

sub select_fruit {
    print "Enter a number to select   (1) Apple (2) Mango (3) grapes:"
    $value=<STDIN>;
    if($value =~ /[^1-3]/ ) {
        print "The input is not valid!";
        print "Do you want to continue selecting a fruit again (Y or N)?";
        $choice = <STDIN>;
        if( $choice eq "y") {
            goto &select_fruit;
          } else {
            exit;
        }
    }
    return $value;
}

or redo

sub select_fruit {
SELECT_FRUIT: {
       print "Enter a number to select   (1) Apple (2) Mango (3) grapes:"
       $value=<STDIN>;
       if($value =~ /[^1-3]/ ) {
           print "The input is not valid!";
           print "Do you want to continue selecting a fruit again (Y or N)?";
           $choice = <STDIN>;
           if( $choice eq "y") {
               redo SELECT_FRUIT; # same as goto SELECT_FRUIT;
             } else {
               exit;
            }
        }
        return $value;
    }
}

and so ...

Answer 7

Use IO::Prompt module.

With it you can write it like this:

use IO::Prompt;
my @choices = qw( Apple Mango Grapes );
my $answer = prompt("Select :", "-menu" => \@choices);
print $answer;

Answer 8

Your input is not eq "y" but "y\n".

If you change the line to if ($choice =~ /^[Yy]/) this will make sure you catch the Y at the start of the input and not worry about y or yes or Y or Yes.

As a help, you should use <STDIN> instead of STDIN alone. Always add use strict; use warnings; at the top. This makes sure you need to define $value and $choice using:

my $value = '';
my $choice = '';

As other people have mentioned. This is probably more straightforward as a loop.

#!/usr/bin/env perl
use strict;
use warnings;

some_routine();

sub some_routine {    
    my $value = '';
    my $choice = '';
    print "Enter a number to select   (1) Apple (2) Mango (3) grapes:";
    $value = <STDIN>;
    if($value !~ /[1-3]/ ) {
        print "The input is not valid!";
        print "Do you want to continue selecting a fruit again (Y or N)?";
        $choice = <STDIN>;
        if( $choice =~ /[Yy]/) {
            some_routine();
          } else {
            exit;
        }
    }
}