Creating array from object function using map

Question

I have an array of HTML::Elements obtained from HTML::TreeBuilder and HTML::Element->find and I need to assign their as_text value to some other variables. I know I can really easily do

my ($var1, $var2) = ($arr[0]->as_text, $arr[1]->as_text);

but I was hoping I could use map instead just to make the code a bit more readable as there are at least 8 elements in the array. I'm really new to Perl so I'm not quite sure what to do.

Can anyone point me in the right direction?

Answer 1

If you're well versed in perldoc -f map it's pretty clear:

my @as_texts = map { $_->as_text } @arr;

Works as well if you want to assign to a list of scalars:

my($var1, $var2, $var3, ...) = map { $_->as_text } @arr;

But of course the array version is better for an unknown number of elements.

Answer 2

Note that, if you just want to map the first two elements of @arr:

my($var1, $var2) = map { $_->as_text } @arr;

will invoke $_->as_text for all elements of @arr. In that case, use an array slice to avoid unnecessary calls:

my($var1, $var2) = map { $_->as_text } @arr[0 .. 1];

Example:

#!/usr/bin/perl

use strict;
use warnings;

my @arr = 'a' .. 'z';
my $count;
my ($x, $y) = map { $count++; ord } @arr;

print "$x\t$y\t$count\n";

$count = 0;
($x, $y) = map { $count++; uc } @arr[0 .. 1];

print "$x\t$y\t$count\n";

Output:

C:\Temp> jk
97      98      26
A       B       2

ord was called for each element of @arr whereas uc was called for only the elements we were interested in.