Concatenating a list of numbers into one integer in haskell

Question

Hi

I am doing yet another euler project question (38). I have this function which returns a list of numbers but what I need is that list of numbers to be one number. It calculates the concatenated product of an integer.

f (a,b) = a*b
conProInt x n  = map f (zip (replicate n x) ([1..n]))

prob38 = maximum [ (conProInt (x) (n)) | x <- [100..500], n <- [1..9], (sort $ nub $ (decToList $ (conProInt x n) )) == (sort $ (decToList $ (conProInt x n) )), (sort $ nub $ (decToList $ (conProInt x n))) == [1..9] ]

eg:

conProInt 192 3

returns: [192,384,576]

what I need returned is: 192384576

I have searched around and can't find a function or think of a function I could construct that would deliver what I need. How would I go about this?

EDIT:

I have updated the script to incorporate faster concatenation, but it doesn't return the correct result:

f (a,b) = a*b
conProInt x n  =( combine (map f (zip (replicate n x) ([1..n]))))
prob38 = maximum [ (conProInt (x) (n)) | x <- [1..50000], n <- [2..40], (sort $ nub $ (decToList $ (conProInt x n) )) == (sort $ (decToList $ (conProInt x n) )), (sort $ nub $ (decToList $ (conProInt x n))) == [1..9] ]

I'm pretty sure the pandigital test:

(sort $ nub $ (decToList $ (conProInt x n) )) == (sort $ (decToList $ (conProInt x n) )), (sort $ nub $ (decToList $ (conProInt x n))) == [1..9]

won't fail and I tried to make the search as large as possible but the maximum 9-pandigital I got was 986315724, any suggestions? Is the range of values for n a very large one?

Answer 1

You can use this function to concatenate a list of numbers:

concatNumbers :: [Int] -> String
concatNumbers = concat . map show

If you want the function to return the concatenation as a number, you can use read.

Answer 2

Going via Strings is probably easiest:

read $ concat $ map (show) [192,384,576]

Though you'll probably need to add a type signature:

Prelude> (read $ concat $ map (show) [192,384,576]) :: Int
192384576

Answer 3

Here's an example of how to concatenate digits without converting to and from character strings.

-- foldl1' is a strict fold.  "foldl1" would also work...
import Data.List (foldl1')    

-- Combine two numbers such that their digits are concatenated.
-- op 1 23 = 123, op 0 12 = 12, op 12345 67 = 1234567
op :: Int -> Int -> Int
op a b = a * power 10 (numDigits b) + b

-- How many digits does a positive number have?
numDigits :: Int -> Int
numDigits x = length . takeWhile (>= 1) . iterate (`div` 10) $ x

-- Take a positive number and raise it to a positive power.
-- power 5 2 = 25, power 10 3 = 1000
power :: Int -> Int -> Int
power x y = foldl1' (*) . take y $ repeat x

-- Take a list of numbers, and concatenate all their digits.
combine :: [Int] -> Int
combine xs = foldl1' op xs

example run:

Prelude> :m +Data.List
Prelude Data.List> let power x y = foldl1' (*) . take y $ repeat x
Prelude Data.List> let numDigits = length . takeWhile (>=1) . iterate (`div` 10)
Prelude Data.List> let op a b = a * power 10 (numDigits b) + b
Prelude Data.List> let combine xs = foldl1' op xs
Prelude Data.List> combine [192, 384, 576]
192384576
Prelude Data.List>