In Perl, how do you access a value from a reference in an array of hashrefs?

Question

I have an array of references to anonymous hashes. From the reference to that array, $allDirArray, I want to access the value corresponding to the key 'dir'. Currently I am getting the error:

Can't use string ("HASH(0x100878050)") as a HASH ref while "strict refs" 
in use at nameOfProgram.pl line 148.

My code:

my $tempDir = ${$allDirArray}[$i]{'dir'};

Answer 1

 $allDirArray->[$i]->{dir}

See perldoc perlreftut.

Now, I think Dan has the right diagnosis of your problem. So, the FAQ What's wrong with always quoting "$vars"? might be helpful.

Answer 2

$$allDirArray[$i]->{'dir'}

Answer 3

I couldn't really see what the problem was with the code you quoted, so I wrote a short test script and passed it through Perl.

#! perl
use warnings;
use strict;

my $allDirArray = [{dir => "b"},{c => "d"}];
my $i = 0;
my $tempDir = ${$allDirArray}[$i]{'dir'};
print "$tempDir\n";

As written above, using Perl 5.10 on Cygwin, the program ran as followed:

$ perl allarraydir.pl
b

No error message was printed. See http://codepad.org/pH4eyMlt

Edit

After including telemachus's suggestion, I added the following code to the end of the above program,

# The following addition was included re telemachus's comment
my @allDirArray2 = ({dir => "b"},{c => "d"});
$tempDir = ${$allDirArray2}[$i]{'dir'};
print "$tempDir\n";

ran it again and got the following error message:

$ perl allarraydir.pl
Global symbol "$allDirArray2" requires explicit package name at 
allarraydir.pl line 10.
Execution of allarraydir.pl aborted due to compilation errors.

(this should really be a comment on your question rather than an answer, but the code is too long.)

Answer 4

The error message suggests you're actually trying to use the string "HASH(0x100878050)" as a hashref. So I suspect you've somehow managed to stringify your hashes (ie, you used them as strings, and Perl turned them into strings for you). One way this can happen is if you assign a hashref to a hash key (hash keys can only be strings), or by quoting variables in an assignment like this $array[0] = "$hashref".

So inside ${$allDirArray}[$i] is a string containing "HASH(0x100878050)", literally that, in a string. Not a hash.

Best bet to confirm this is probably to dump the data structure. You can do this with Data::Dumper:

use Data::Dumper;
print Dumper($allDirArray);

Answer 5

Somehow you managed to make your anonymous hash into a string.

Here is a short example that causes that error.

use strict;
use warnings;

my $allDirArray = [ ''.{ 'dir' => 'somedir' } ];

my $tempdir = ${$allDirArray}[0]{'dir'};
# or
my $tempdir = $allDirArray->[0]{'dir'};

Can't use string ("HASH(0x8555168)") as a HASH ref while "strict refs" in use at nameOfProgram.pl line 8.